??函數公式我們在工作中經常用到，那excel如何使用函數公式呢?下面就是excel使用函數公式教程，一起來看看吧。

??excel函數公式實例大全

??excel函數公式收集了688個實例，涉及到137個函數、7個行業、41類用途，為大家提供一個參考，拓展思路的機會。公式由{}包括的為數組公式，在復制粘貼到單元后先去掉{}然后按住Shift鍵+Ctrl鍵再按Enter鍵，自動生成數組公式。

??對三組生產數據求和:=SUM(B2:B7,D2:D7,F2:F7)

??對生產表中大于100的產量進行求和:{=SUM((B2:B11>100)*B2:B11)}

??對生產表大于110或者小于100的數據求和:{=SUM(((B2:B11<100)+(B2:B11>110))*B2:B11)}

??對一車間男性職工的工資求和:{=SUM((B2:B10="一車間")*(C2:C10="男")*D2:D10)}

??對姓趙的女職工工資求和:{=SUM((LEFT(A2:A10)="趙")*(C2:C10="女")*D2:D10)}

??求前三名產量之和:=SUM(LARGE(B2:B10,{1,2,3}))

??求所有工作表相同區域數據之和:=SUM(A組:E組!B2:B9)

??求圖書訂購價格總和:{=SUM((B2:E2=參考價格!A$2:A$7)*參考價格!B$2:B$7)}

??求當前表以外的所有工作表相同區域的總和:=SUM(一月:五月!B2)

??用SUM函數計數:{=SUM((B2:B9="男")*1)}

??求1累加到100之和:{=SUM(ROW(1:100))}

??多個工作表不同區域求前三名產量和:{=SUM(LARGE(CHOOSE({1,2,3,4,5},A組!B2:B9,B組!B2:B9,C組!B2:B9,D組!B2:B9,E組!B2:B9),ROW(1:3)))}

??計算倉庫進庫數量之和:=SUMIF(B2:B10,"=進庫",C2:C10)

??計算倉庫大額進庫數量之和:=SUMIF(B2:B8,">1000")

??對1400到1600之間的工資求和:{=SUM(SUMIF(B2:B10,"<="&{1400,1600})*{-1,1})}

??求前三名和后三名的數據之和:=SUMIF(B2:B10,">"&LARGE(B2:B10,4))+SUMIF(B2:B10,"<"&SMALL(B2:B10,4))

??對所有車間人員的工資求和:=SUMIF(A2:A10,"?車間",C2)

??對多個車間人員的工資求和:=SUMIF(A2:A10,"??車間*",C2)

??匯總姓趙、劉、李的業務員提成金額:=SUM(SUMIF(A2:A10,{"趙","劉","李"}&"*",C2:C10))

??匯總鼠標所在列中大于600的數據:=SUMIF(INDIRECT("R2C"&CELL("col")&":R8C"&CELL("col"),FALSE),">600")

??只匯總60～80分的成績:=SUMIFS(B2:B10,B2:B10,">=60",B2:B10,"<=80")

??匯總三年級二班人員遲到次數:=SUMIFS(D2:D10,B2:B10,"三年級",C2:C10,"二班")

??匯總車間女性人數:=SUMIFS(C2:C11,A2:A11,"*車間",B2:B11,"女")

??計算車間男性與女性人員的差:=SUM(SUMIFS(C2:C11,B2:B11,{"女","男"},A2:A11,"*車間")*{-1,1})

??計算參保人數:=SUMPRODUCT((C2:C11="是")*1)

??求25歲以上男性人數:=SUMPRODUCT((B2:B10="男")*1,(C2:C10>25)*1)

??匯總一班人員獲獎次數:=SUMPRODUCT((B2:B11="一班")*C2:C11)

??匯總一車間男性參保人數:=SUMPRODUCT((A2:A10&B2:B10&C2:C10="一車間男是")*1)

??匯總所有車間人員工資:=SUMPRODUCT(--NOT(ISERROR(FIND("車間",A2:A10))),C2:C10)

??匯總業務員業績:=SUMPRODUCT((B2:B11={"江西","廣東"})*(C2:C11="男")*D2:D11)

??根據直角三角形之勾、股求其弦長:=POWER(SUMSQ(B1,B2),1/2)

??計算A1：A10區域正數的平方和:{=SUMSQ(IF(A1:A10>0,A1:A10))}

??根據二邊長判斷三角形是否為直角三角形:=CHOOSE((SUMSQ(MAX(B1:B3))=SUMSQ(LARGE(B1:B3,{2,3})))+1,"非直角","直角")

??計算1到10的自然數的積:=FACT(10)

??計算50到60之間的整數相乘的結果:=FACT(60)/FACT(49)

??計算1到15之間奇數相乘的結果:=FACTDOUBLE(15)

??計算每小時生產產值:=PRODUCT(C2:E2)

??根據三邊求普通三角形面積:=(PRODUCT(SUM(B1:B3)/2,SUM(B1:B3)/2-LARGE(B1:B3,{1,2,3})))^0.5

??根據直角三角形三邊求三角形面積:=PRODUCT(LARGE(B1:B3,{2,3}))/2

??跨表求積:=PRODUCT(產量表:單價表!B2)

??求不同單價下的利潤:{=MMULT(B2:B10,G2:H2)*25%}

??制作中文九九乘法表:=COLUMN()&"*"&ROW()&"="&MMULT(ROW(),COLUMN())

??計算車間盈虧:=SUM(MMULT((B3:E5>0)*B3:E5,{1;1;1;1}),MMULT((B3:E5<0)*B3:E5,{1;1;1;1}))

??計算各組別第三名產量是多少:{=MAX(MMULT(COLUMN(A:E)^0,B2:G6))}

??計算C產品最大入庫量:{=MAX(MMULT(N(A2:A11="C"),TRANSPOSE((B2:B11)*(A2:A11="C"))))}

??求入庫最多的產品數量:{=MAX(MMULT(TRANSPOSE((B2:B11)*(A2:A11={"A","B","C","D"})),(A2:A11={"A","B","C","D"})*1))}

??計算累計入庫數:{=MMULT(N(ROW(2:11)>=TRANSPOSE(ROW(2:11))),B2:B11)}

??計算每日庫存數:{=MMULT(N(ROW(2:11)>=TRANSPOSE(ROW(2:11))),B2:B11-C2:C11)}

??計算A產品每日庫存數:{=MMULT(N(ROW(2:17)>=TRANSPOSE(ROW(2:17))),(B2:B17="A")*(C2:C17-D2:D17))}

??求第一名人員最多有幾次:{=MAX(MMULT(N(B2:B7=TRANSPOSE(B2:B7)),ROW(2:7)^0))}

??求幾號選手選票最多:{=RIGHT(MAX(MMULT(N(B2:B10=TRANSPOSE(B2:B10)),ROW(2:10)^0)*100+B2:B10))}

??總共有幾個選手參選:{=SUM(1/(MMULT(N(B2:B10=TRANSPOSE(B2:B10)),ROW(2:10)^0)))}

??在不同班級有同名前提下計算學生人數:{=SUM(1/MMULT(N(A2:A17&B2:B17&C2:C17=TRANSPOSE(A2:A17&B2:B17&C2:C17)),ROW(2:17)^0))}

??計算前進中學參賽人數:{=SUM(IFERROR(1/MMULT(N((A2:A17&B2:B17&C2:C17=TRANSPOSE(A2:A17&B2:B17&C2:C17))*(A2:A17="前進中學")),ROW(2:17)^0),0))}

??串聯單元格中的數字:{=MMULT(10^(COLUMNS(B:K)-COLUMN(C:L)),TRANSPOSE(B2:K2))}或=SUMPRODUCT(B2:K2,10^(COLUMNS(B:K)-COLUMN(B:K)-1))

??計算達標率:{=MMULT(TRANSPOSE(N(A2:A11<=(B2:B11))),ROW(2:11)^0)/ROWS(2:11)}

??計算成績在60-80分之間合計數與個數:求和{=MMULT(TRANSPOSE((B2:B11>60)*(B2:B11<80)*B2:B11),ROW(2:11)^0)}，求個數{=MMULT(TRANSPOSE((B2:B11>60)*(B2:B11<80)),ROW(2:11)^0)}

??匯總A組男職工的工資:{=MMULT(TRANSPOSE(N(B2:B11&C2:C11="男A組")*D2:D11),ROW(2:11)^0)}

??計算象棋比賽對局次數l:=COMBIN(B1,B2)

??計算五項比賽對局總次數:{=SUM(COMBIN(B2:B5,2))}

??預計所有賽事完成的時間:=COMBIN(B1,B2)*B3/B4/60

??計算英文字母區分大小寫做密碼的組數:=PERMUT(B1*2,B2)

??計算中獎率:=TEXT(1/PERMUT(B1,B2),"0.00%")

??計算最大公約數:=GCD(B1:B5)

??計算最小公倍數:=LCM(B1:B5)

??計算余數:=MOD(A2,B2)

??匯總奇數行數據:=SUMPRODUCT(MOD(ROW(2:13),2)*C2:C13)

??根據單價數量匯總金額:=SUMPRODUCT(MOD(COLUMN(A:I),2)*A2:I2,(MOD(COLUMN(B:J),2)=0)*B2:J2)

??設計工資條:=IF(MOD(ROW(),3)=1,單行表頭工資明細!A$1,IF(MOD(ROW(),3)=2,OFFSET(單行表頭工資明細!A$1,ROW()/3+1,0),""))

??根據身份證號計算性別:=IF(MOD(MID(B2,15,3),2),"男","女")

??每隔4行合計產值:=IF(MOD(ROW(),5)=1,SUM(OFFSET(F2,-4,,4,)),D2*E2)

??工資截尾取整:=B2+MOD(一月!B2,10)-MOD(B2+MOD(一月!B2,10),10)

??匯總3的倍數列的數據:{=SUM(IF(MOD(COLUMN(A:I),3)=0,A2:I10))}

??將數值逐位相加成一位數:=IF(A2=0,0,MOD(A2-1,9)+1)

??計算零鈔:5角=INT(MOD(SUM(B2:B10),1)/0.5);2角=INT(MOD(MOD(SUM(B2:B10),1),0.5)/0.2);1角=MOD(MOD(MOD(SUM(B2:B10),1),0.5),0.2)/0.1

??秒與小時、分鐘的換算:=QUOTIENT(MOD($A2,IF(COLUMN()=2,A2+1,60^(3-COLUMN(A:A)+1))),60^(3-COLUMN(A:A)))

??生成隔行累加的序列:=QUOTIENT(ROW()+1,2)

??根據業績計算業務員獎金:=CHOOSE(MIN(QUOTIENT(B2,10000)+1,6),0,3%,5%,7%,9%,11%)*B2

??計算預報溫度與實際溫度的最大誤差值:{=MAX(ABS(C2:C8-B2:B8))}

??計算個人所得稅:=ROUND(0.05*SUM(H2-1600-{0,500,2000,5000,20000,40000,60000,80000,100000}+ABS(H2-1600-{0,500,2000,5000,20000,40000,60000,80000,100000}))/2,0)

??產生100到200之間帶小數的隨機數:=RAND()*(200-100)+100

??產生ll到20之間的不重復隨機整數:{=RANK(A2:A11,A2:A11)+10}

??將20個學生的考位隨機排列:{=INDEX(A$2:A$11,RANK(H2:H11,H2:H11))}

??將三個學校植樹人員隨機分組:=OFFSET(A$1,RANK(G2,G$2:G$11),)&":"&OFFSET(B$1,RANK(G2,G$2:G$11),)&":"&OFFSET(C$1,RANK(G2,G$2:G$11),)

??產生-50到100之間的隨機整數:=RANDBETWEEN(-50,100)

??產生1到100之問的奇數隨機數:{=INDEX(IF(MOD(ROW(1:100),2),ROW(1:100),ROW(1:100)-1),RANDBETWEEN(1,100))}

??產生1到10之間隨機不重復數:{=LARGE(IF(COUNTIF(A$1:A1,ROW($1:$10))=0,ROW($1:$10)),RANDBETWEEN(1,12-ROW()))}

??根據三角形三邊長求證三角形是直角三角形:=IF(POWER(MAX(B1:B3),2)=SUM(POWER(LARGE(B1:B3,{2,3}),2)),"是","不是")

??計算Al:A10區域開三次方之平均值:{=AVERAGE(POWER(A1:A10,1/30))}

??計算Al:A10區域倒數之積:{=PRODUCT(POWER(A1:A10,-1))}

??根據等邊三角形周長計算面積:=SQRT(B1/2*POWER(B1/2-B1/3,3))

??抽取奇數行姓名:=INDEX(B:B,ODD(RANDBETWEEN(1,ROWS(1:12)-1)))

??統計A1:B10區域中奇數個數:=SUMPRODUCT(N(ODD(A1:B10)=(A1:B10)))

??統計參考人數:=SUMPRODUCT((EVEN(COLUMN(A1:J12))=COLUMN(A1:J12))*(MOD(ROW(A1:J12),3)=1)*(A1:J12<>""))

??計算A1:B10區域中偶數個數:=SUMPRODUCT(N(EVEN(A1:B10)=(A1:B10)))

??合計購物金額、保留一位小數:=TRUNC(SUMPRODUCT(B2:B10,C2:C10),1)

??將每項購物金額保留一位小數再合計:=SUMPRODUCT(TRUNC(B2:B10*C2:C10,1))

??將金額進行四舍六入五單雙:=IF((A2-TRUNC(A2,1))<=0.04,TRUNC(A2,1),IF((A2-TRUNC(A2,1))>=0.06,TRUNC(A2,1)+0.1,TRUNC((TRUNC(A2,1)+0.1)/2,1)*2))

??根據重量單價計算金額，結果以萬為單位:=TRUNC(SUMPRODUCT(B2:B10,C2:C10),-4)/10000

??計算年假天數:=TRUNC((TODAY()-B2)*((TODAY()-B2)>=365)/365*5)

??根據上機時間計算上網費用:=(TRUNC(B2)+(B2-TRUNC(B2)>=0.5))*1.5+(MOD(B2,1)<0.5)

??將金額見角進元與見分進元:見分進元=CEILING(TRUNC(A2,2),1);見角進元=CEILING(TRUNC(A2,1),1)

??分別統計收支金額并忽略小數:收入合計=SUMPRODUCT(INT(B2:B8));支出合計=SUMPRODUCT(TRUNC(C2:C8))

??成績表的格式轉換:姓名=INDEX(A:A,INT((ROW(A6))/3));科目=INDEX(B$1:D$1,1,MOD((ROW(A1)-1),3)+1);成績=INDEX($B$2:$D$7,INT((ROW(A1)-1)/3)+1,MOD((ROW(A1)-1),3)+1)

??隔兩行進行編號:=IF(MOD(ROW(),3)=1,INT(ROW(A3)/3),"")

??INT函數在序列中的復雜運用:=INT(SQRT(2*ROW(A1))+0.5);=10^INT((ROW()-1)/2);=INT(10^(ROW())/9);=INT((ROW(A2))*2/3)

??統計交易損失金額:=SUMPRODUCT(B2:B11-CEILING(B2:B11,0.1))

??根據員工工齡計算年資:=C2+CEILING(B2*30,30)*(INT(B2)>0)

??成績表轉換:=INDEX($A:$E,CEILING(ROW()*3/5,3)-(COLUMN()=7),MOD(ROW(B2)-1,5)+1)

??計算機上網費用:=CEILING(B2,30)/30*2

??統計可組建的球隊總數:=SUMPRODUCT(FLOOR(B2:B10,5)/5)

??統計業務員提成金額，不足20000元忽略:=FLOOR(B2,20000)/20000*500

??FLOOR函數處理正負數混合區域:=FLOOR(A1*100,10*(IF(A1>0,1,-10)))

??將數據轉換成接近6的倍數:=MROUND(A1,6)

??以超產80為單位計算超產獎:{=SUM(MROUND(B2:B11-700,80*IF(B2:B11>=700,1,-1)))/80*50}

??將統計金額保留到分位:=ROUND(SUMPRODUCT(B2:B10,C2:C10),2)

??將統計金額轉換成以萬元為單位:=ROUND(SUMPRODUCT(B2:B10,C2:C10)%%,)

??對單價計量單位不同的品名匯總金額:{=SUM(ROUND(B2:B10*C2:C10*IF(D2:D10="G",1000,1),(D2:D10="G")*2))}

??將金額保留“角”位，忽略“分”位:{=SUM(ROUNDDOWN(B2:B10*C2:C10,1))}

??計算需要多少零鈔:{=SUM(ROUNDDOWN(B2:B10*C2:C10,{0,-1})*{1,-1})}

??計算值為l萬的整數倍數的數據個數:{=SUM(N((B2:B10*C2:C10)=ROUNDDOWN(B2:B10*C2:C10,-4)))}

??計算完成工程需求人數:{=SUM(ROUNDUP(B2:B11/C2:C11,))}

??按需求對成績進行分類匯總:=SUBTOTAL(HLOOKUP(G$1,{"平均成績","科目數量","最高成績","最低成績","成績合計";1,2,4,5,9},2,0),B2:D2)

??不間斷的序號:=SUBTOTAL(103,$B$2:B2)

??僅對篩選出的人員排名次:{=CONCATENATE("第",SUM(N(IF((SUBTOTAL(103,OFFSET(優等生!A$1,ROW($2:$31)-2,)))=1,$C$2:$C$31,)>C2))+1,"名")}

??判斷兩列數據是否相等:

??計算兩列數據同行相等的個數:{=SUM(N(A1:A10=B1:B10))}

??計算同行相等且長度為3的個數:{=SUM((A1:A10=B1:B10)*(LEN(A1:A10)=3))}

??提取A產品最后單價:{=INDEX(C:C,MAX((B2:B10="A")*ROW(2:10)))}

??判斷學生是否符合獎學金發放條件:=AND(B2>90,C2<>"漢族")

??所有裁判都給“通過”就進入決賽:{=AND(B2:E2="通過")}

??判斷身份證長度是否正確:=OR(LEN(B2)={15,18})

??判斷歌手是否被淘汰:{=OR(B2:E2="不通過")}

??根據年齡判斷職工是否退休:=OR(AND(B2="男",C2>60),AND(B2="女",C2>55))

??根據年齡與職務判斷職工是否退休:=OR(AND(B2="男",D2>60+(C2="干部")*3),AND(B2="女",D2>55+(C2="干部")*3))

??沒有任何裁判給“不通過”就進行決賽:{=NOT(OR(B2:E2="不通過"))}

??計彝成績區域數字個數:{=SUM(NOT(ISERROR(NOT(B2:B11)))*1)}

??評定學生成績是否及格:=IF(AVERAGE(B2:D2)>=60,"及格","不及格")

??根據學生成績自動產生評語:=IF(AVERAGE(B2:D2)<60,"不及格",IF(AVERAGE(B2:D2)<90,"良好",IF(AVERAGE(B2:D2)<100,"優秀","滿分")))

??根據業績計算需要發放多少獎金:{=SUM(IF(B2:B11>80000,1000,500))}

??根據工作時間計算12月工資:=C2+SUM(IF(B2>{0,1,3,5,10},{300,500,500,500,500}))

??合計區域的值并忽略錯誤值:{=SUM(IF(ISERROR(A1:C10),0,A1:C10))}

??既求積也求和:=IF(D2<>"",PRODUCT(C2:D2),SUM(OFFSET(E2,-3,,3)))

??分別統計收入和支出:收入{=SUM(IF(B2:B13>0,B2:B13))};支出{=SUM(IF(SUBSTITUTE(IF(B2:B13<>"",B2:B13,0),"負","-")*1<0,SUBSTITUTE(B2:B13,"負","-")*1))}

??將成績從大到小排列:{=IF(ROW(A1)>COUNT(B$2:B$11),"",LARGE(B$2:B$11,ROW(A1)))}

??排除空值:{=INDEX($A:$B,SMALL(IF($B$1:$B$11<>"",ROW($1:$11),ROWS($1:$11)+1),ROW()),COLUMN(B2))&""}

??有選擇地匯總數據:{=SUM(IF(A2:A11={"A組","C組"},C2:C11))}

??混合單價求金額合計:{=SUM(ROUND(B2:B10*C2:C10*IF(D2:D10="K",1000,1),2))}

??計算異常停機時間:{=SUM(SUBSTITUTE(SUBSTITUTE(IF(C2:C11<>"",C2:C11,0),"修機",""),"換原料","")*1)}

??計算最大數字行與文本行:{=MAX(IF(B:B<>"",ROW(A:A)))}

??找出誰奪冠次數最多:{=INDEX(B:B,MIN(IF(MAX(COUNTIF(B2:B12,B2:B12))=COUNTIF(B2:B12,B2:B12),ROW(2:12))))}

??將全角字符轉換為半角:=ASC(A2)

??計算漢字全角半角混合字符串中的字母個數:=LEN(ASC(A2))*2-LENB(ASC(A2))

??將半角字符轉換成全角顯示:=WIDECHAR(A2)

??計算混合字符串中漢字個數:=LEN(A2)-(LENB(WIDECHAR(A2))-LENB(ASC(A2)))

??判斷單元格首字符是否為字母:=OR(AND(CODE(A2)>64,CODE(A2)<91),AND(CODE(A2)>96,CODE(A2)<123))

??計算單元格中數字個數:{=SUM((CODE(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))>47)*(CODE(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))<58))}

??計算單元格中大寫加小寫字母個數:{=SUM((CODE(UPPER(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)))>64)*(CODE(UPPER(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)))<91))}

??產生大、小寫字母A到Z的序列:大寫字母=CHAR(ROW(A65))，小寫字母=CHAR(ROW(A65)+32)

??產生大寫字母A到ZZ的字母序列:=IF(ROW()<27,CHAR(MOD(ROW()-1,26)+65),CHAR(65+(ROW()-1)/26-1))&IF(ROW()>26,CHAR(MOD(ROW()-1,26)+65),"")

??產生三個字母組成的隨機字符串:=CHAR(RANDBETWEEN(65,90))&CHAR(RANDBETWEEN(65,90))&CHAR(RANDBETWEEN(65,90))

??用公式產生換行符:=A2&CHAR(10)&B2

??將數字轉換成英文字符:字符碼=RANDBETWEEN(1,100)，升序位置=CHAR(MOD(A1-1,26)+65)

??將字母升序排序:{=CHAR(SMALL(CODE(A$2:A$13),ROW(A1)))}

??返回自動換行單元格的第二行數據:=RIGHT(A2,LEN(A2)-FIND(CHAR(10),A2))

??根據身份證號碼提取出生年月日:=CONCATENATE(MID(B2,7,4-2*(LEN(B2)=15)),"年",MID(B2,11-2*(LEN(B2)=15),2),"月",MID(B2,13-2*(LEN(B2)=15),2),"日?")

??計算平均成績及評判是否及格:=CONCATENATE(INT(AVERAGE(B2:D2)),":?",IF(AVERAGE(B2:D2)>=60,"","不"),"及格")

??提取前三名人員姓名:=CONCATENATE(LOOKUP(0,0/(B2:B11=LARGE(B2:B11,1)),A2:A11),"|",LOOKUP(0,0/(B2:B11=LARGE(B2:B11,2)),A2:A11),"|",(LOOKUP(0,0/(B2:B11=LARGE(B2:B11,3)),A2:A11)))

??將單詞轉換成首字母大寫:=PROPER(A2)

??將所有單詞轉換成小寫形式:=LOWER(A2)

??將所有句子轉換成首字母大寫其余小寫:=CONCATENATE(PROPER(LEFT(A2)),LOWER(RIGHT(A2,LEN(A2)-1)))

??將所有字母轉換成大寫形式:=UPPER(A2)

??計算字符串中英文字母個數:{=SUM(N(NOT(EXACT(UPPER(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)),LOWER(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1))))))}

??計算字符串中單詞個數:{=SUM(N(EXACT(TRIM(MID(UPPER(A2),ROW(INDIRECT("1:"&LEN(A2))),1)),MID(PROPER(A2),ROW(INDIRECT("1:"&LEN(A2))),1))))}

??將文本型數字轉換成數值:{=SUM(VALUE(B2:B10))}

??計算字符串中的數字個數:=SUMPRODUCT(N(ISNUMBER(VALUE(MID(A2,ROW($1:$100),1)*1))))

??提取混合字符串中的數字:{=MAX(IFERROR(VALUE(MID(A2,MIN(FIND({0;1;2;3;4;5;6;7;8;9},A2&1234567890)),ROW(INDI

??串聯區域中的文本:=CONCATENATE(T(A2),T(B2),T(C2))

??給公式添加運算說明:=CONCATENATE("你好",B2,"2008")&T(N("公式含義:連接“你好”和單元格B2、“2008”"))

??根據身份證號碼判斷性別:=TEXT(MOD(MID(B2,15,3),2),"[=1]男;[=0]女")

??將所有數據轉換成保留兩位小數再求和:{=SUM(--TEXT(B2:B11*C2:C11,"0.00"))}

??將貨款顯示為“萬元”為單位:=TEXT(B2,"￥#"&""""&"."&""""&"#,萬元")

??根據身份證號碼計算出生日期:=IF(LEN(B2)=15,19,"")&TEXT(MID(B2,7,8-(LEN(B2)=15)*2),"#年00月00日")

??顯示今天的英文日期及星期:="資料日期："&TEXT(TODAY(),"dddd,?mmmm?dd,?yyyy")

??顯示今天每項工程的預計完成時間:=TEXT(SUM("08:00",B$2:B2),"h:mm:ss?上午/下午")

??統計A列有多少個星期日:{=SUM(N(TEXT(A1:A11,"aaa")="日"))}

??將數據顯示為小數點對齊:=TEXT(B2,"#.0????")

??計算A列的日期有幾個屬于第二季度:{=SUM((--(TEXT(A1:A11,"m"))>{3,6})*{1,-1})}

??在A列產生1到12月的英文月份名:=TEXT((ROW())&"-1","mmmm")

??將日期顯示為中文大寫:=TEXT("2008-8-10","[DBNum2]yyyy年m月d日")

??將數字金額顯示為人民幣大寫:=IF(MOD(B2,1)=0,TEXT(INT(B2),"[dbnum2]G/通用格式元整;負[dbnum2]G/通用格式元整;零元整;"),IF(B2>0,,"負")&TEXT(INT(ABS(B2)),"[dbnum2]G/通用格式元;;")&SUBSTITUTE(SUBSTITUTE(TEXT(RIGHT(FIXED(B2),2),"[dbnum2]0角0分;;"),"零角",IF(ABS(B2)<>0,,"零")),"零分",""))

??判斷單元格的數據類型:=TEXT(A2,"大于○;小于○;○;文本")

??計算達成率，以不同格式顯示:=TEXT(B2/800,"[>=1]0.0倍;[>0]0.00%;")

??計算字母“A”的首次出現位置，忽略大小寫:=TEXT(SEARCH("a",A2&"a"),"[>"&LEN(A2)&"]沒找到;第"&SEARCH("a",A2&"a")&"個")

??從身份證號碼中提取表示性別的數字:=MID(B2,TEXT(LEN(B2),"[=15]15;17"),1)

??將三列數據交換位置:{=TEXT({1,-1,0},C1:C5&";"&"!"&B1:B5&";"&A1:A5)}

??計算年終獎:=TEXT(B2,"[>3]15!0!0;[>1]1!0!0!0;5!0!0;")

??計算星期日完工的工程個數:{=COUNT((TEXT(B2:B10+C2:C10-1,"AAA")="日")^0)}

??計算本月星期日的個數:{=SUM(N(TEXT(TODAY()-TEXT(TODAY(),"d")+ROW(INDIRECT("1:"&DAY(DATE(,TEXT(TODAY(),"m")+1,)))),"AAA")="日"))}

??檢驗日期是否升序排列:=TEXT(N(A3>=A2),";;日期有誤;")

??判斷單元格中首字符的類型:=TEXT(IF(AND(CODE(UPPER(A3))>64,CODE(UPPER(A3))<91),CODE(A3),A3),"[="&CODE(A3)&"]字母;;數字;漢字")

??計算每個季度的天數:{=SUM(--TEXT(DATE(2008,3*ROW(A1)-ROW($1:$3)+2,),"d"))}

??將數據重復顯示5次:=SUBSTITUTE(TEXT(A2&"?","@@@@@"),"?","")

??將表示起止時間的數字格式化為時間格式:=TEXT(B2,"#!:00-00!:00")

??根據起止時間計算經過時間:=TEXT(INT(((TEXT(RIGHT(B4,4),"#!:00")-TEXT(LEFT(B4,3+(LEN(B4)=8)),"#!:00"))*24*60)/60)+MOD(((TEXT(RIGHT(B4,4),"#!:00")-TEXT(LEFT(B4,3+(LEN(B4)=8)),"#!:00"))*24*60),60.1)%,"0小時.00分鐘")

??將數字轉化成電話格式:=TEXT(A2,"(0000)0000-0000")

??在A1:A7區域產生星期一到星期日的英文全稱:{=TEXT(ROW(1:7)+1,"DDDD")}

??將匯總金額保留一位小數并顯示千分位分隔符:{=FIXED(SUM(--FIXED(B2:B11*C2:C11,1)),1,FALSE)}

??計算訂單金額并以“百萬”為單位顯示:=FIXED(SUMPRODUCT(B2:B10,C2:C10),-6)/1000000

??將數據對齊顯示，將空白以“.”占位:=WIDECHAR(REPT(".",10-LEN(B2))&B2)

??利用公式制作簡易圖表:=IF(B2>0,REPT("?",5)&"|"&REPT("■",ABS(B2))&B2&REPT("?",5-ABS(B2)),REPT("?",5-ABS(B2)-LEN(B2)/2)&B2&REPT("■",ABS(B2))&"|"&REPT("?",5))

??利用公式制作帶軸的圖表且標示升降:{=IF(A2<>"",A2&"┫","")&IF(A2="",REPT("〓",(MAX(ABS(B$2:B$8))+6)*2),IF(B2>0,REPT("?",4+MAX(ABS(B$2:B$8)))&IF(ROW()=2,"?",IF(B2=OFFSET(B2,-1,0),"→",IF(B2>OFFSET(B2,-1,0),"↑","↓")))&REPT("■",ABS(B2))&B2&REPT("?",4+MAX(ABS(B$2:B$8))-ABS(B2)),REPT("?",4+MAX(ABS(B$2:B$8))-ABS(B2)-LEN(B2)/2)&B2&REPT("■",ABS(B2))&IF(ROW()=1,"?",IF(B2=OFFSET(B2,-1,0),"→",IF(B2>OFFSET(B2,-1,0),"↑","↓"))&REPT("?",4+MAX(ABS(B$2:B$8))))))}

??計算單元格中數字個數:=LEN(A2)*2-LENB(A2)

??將數字倒序排列:{=TEXT(SUM(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)*10^(ROW(INDIRECT("1:"&LEN(A2)))-1)),REPT(0,LEN(A2)))}

??計算購物金額中小數位數最多是幾:{=MAX(LEN(B2:B10*C2:C10)-LEN(INT(B2:B10*C2:C10)))-1}

??計算英文句子中有幾個單詞:=LEN(A2)-LEN(SUBSTITUTE(SUBSTITUTE(A2,"\'","?"),"?",""))+1

??將英文句子規范化:=PROPER(LEFT(A2))&TRIM(RIGHT(A2,LEN(A2)-1))

??分別提取省市縣名:=TRIM(MID(SUBSTITUTE($A2,"/",REPT("?",100)),COLUMN(A2)*100-99,100))

??提取英文名字:=LEFT(A2,FIND("?",A2)-1)

??將分數轉換成小數:=(LEFT(A2,FIND("/",A2)-1)+RIGHT(A2,LEN(A2)-FIND("/",A2)))/2

??從英文短句中提取每一個單詞:=IFERROR(MID($A2,FIND("~",SUBSTITUTE("?"&$A2&"?","?","~",COLUMN(A2))),FIND("~",SUBSTITUTE("?"&$A2&"?","?","~",COLUMN(B2)))-FIND("~",SUBSTITUTE("?"&$A2&"?","?","~",COLUMN(A2)))),"")

??將單位為“雙”與“片”混合的數量匯總:{=SUM(IF(ISNUMBER(FIND("/",C2:C9)),(LEFT(C2:C9,FIND("/",C2:C9)-1)+RIGHT(C2:C9,LEN(C2:C9)-FIND("/",C2:C9)))/2,C2:C9*IF(B2:B9="片",0.5,1)))}

??提取工作表名:=RIGHT(CELL("filename"),LEN(CELL("filename"))-FIND("]",CELL("filename")))

??根據產品規格計算產品體積:=PRODUCT(LEFT(B2,FIND("*",B2)-1),MID(B2,FIND("*",B2)+1,FIND("*",B2,FIND("*",B2)+1)-1-FIND("*",B2)),RIGHT(B2,LEN(B2)-FIND("*",B2,FIND("*",B2)+1)))

??提取括號中的字符串:=IFERROR(MID(A2,FIND("(",A2)+1,FIND(")",A2)-FIND("(",A2)-1),"")

??分別提取長、寬、高:=MID($B2,FIND("@",SUBSTITUTE($B2,"(","@",COLUMN(A1)))+1,FIND("@",SUBSTITUTE($B2,")","@",COLUMN(A1)))-FIND("@",SUBSTITUTE($B2,"(","@",COLUMN(A1)))-1)

??提取學校與醫院地址:{=IF(OR(IFERROR(FIND({"學校","醫院"},A2),FALSE)),A2,"")}

??計算密碼字符串中字符個數:{=COUNT(FIND(CHAR(ROW(65:90)),A2),FIND(CHAR(ROW(97:122)),A2),FIND(ROW(1:10)-1,A2))}

??通訊錄單列轉三列:{=MID(INDEX($A:$A,SMALL(IF(IFERROR(FIND(C$1,$A$1:$A$15),FALSE),ROW($1:$15),100000),ROW(A1))),LEN(C$1)+1,100)}

??將15位身份證號碼升級為18位:{=IF(LEN(B2)=18,B2,LEFT(REPLACE(B2,7,,19),17)&MID("10X98765432",MOD(SUM(MID(REPLACE(B2,7,,19),ROW(INDIRECT("1:17")),1)*2^(18-ROW(INDIRECT("1:17")))),11)+1,1))}

??將產品型號規范化:=IF(MID(A2,5,2)="00",A2,REPLACE(A2,5,,"00"))

??求最大時間:{=TEXT(MAX(--TEXT(REPLACE(LEFT(A2:A7,7),5,1,RIGHT(A2:A7,2)),"00!:00?00-00")),"hmm/dd/mm")}

??分別提取小時、分鐘、秒:=REPLACE(REPLACE($A$1&$A2,FIND(B$1,$A$1&$A2),100,),1,FIND(A$1,$A$1&$A2)+1,)

??將年級或者專業與班級名稱分開:{=REPLACE(A2,MAX(IFERROR(SEARCH(CHAR(ROW($65:$90)),A

??提取各軟件的版本號:=REPLACE(REPLACE(A2,1,SEARCH("(",A2),),LEN(REPLACE(A2,1,SEARCH("(",A2),)),1,)

??店名分類:=IF(COUNT(SEARCH({"小吃","酒吧","茶","咖啡","電影","休閑","網吧"},A2))=1,"餐飲娛樂",IF(COUNT(SEARCH({"干洗","醫院","藥","茶","蛋糕","面包","物流","駕校","開鎖","家政","裝飾","搬家","維修","中介","衛生","旅館"},A2))=1,"便民服務",IF(COUNT(SEARCH({"游樂場","旅行社","旅游"},A2))=1,"旅游")))

??查找編號中重復出現的數字:重復數字個數{=COUNT(SEARCH((ROW($1:$10)-1)&"*"&(ROW($1:$10)-1),A2))};重復字符=IF(COUNT(SEARCH("0*0",A2)),0,"")&SUBSTITUTE(SUMPRODUCT(ISNUMBER(SEARCH(ROW($1:$9)&"*"&ROW($1:$9),A2))*ROW($1:$9)*10^(9-ROW($1:$9))),0,)

??統計名為“劉星”者人數:{=COUNT(SEARCH("?劉星",A2:A9))}

??剔除多余的省名:=SUBSTITUTE(A2,IF(ISERROR(SEARCH("重慶市",A2)),"","四川省"),"")

??將日期規范化再求差:=SUBSTITUTE(C2,".","-")-SUBSTITUTE(B2,".","-")

??提取兩個符號之間的字符串:=TRIM(MID(SUBSTITUTE(B2,"*",REPT("?",50)),FIND("*",B2),100))

??產品規格格式轉換:=SUBSTITUTE(SUBSTITUTE(A2,"：","("),"*",")*")&")"

??判斷調色配方中是否包含色粉“B”:=LEN(SUBSTITUTE(B2,"B",""))<>LEN(B2)

??提取姓名與省份:=TRIM(MID(A2,1,FIND("|",A2)-1)&MID(SUBSTITUTE(A2,"|",REPT("?",100)),500,100))

??將IP地址規范化:=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE("."&A2,".0","."),".0","."),".","",1)

??提取最后一次短跑成績:=REPLACE(A2,1,FIND("々",SUBSTITUTE(A2,"|","々",LEN(A2)-LEN(SUBSTITUTE(A2,"|",)))),)

??從地址中提取省名:=LEFT(A2,FIND("省",A2))

??計算小學參賽者人數:{=COUNT(0/(LEFT(B2:B11)="小"))}

??計算四川方向飛機票總價:=SUMPRODUCT(N(LEFT(A2:A11,2)="四川"),N(B2:B11="飛機"),C2:C11)

??通過身份證號碼計算年齡:=TEXT(TODAY(),"YYYY")-(IF(LEN(B2)=18,"",19)&LEFT(REPLACE(B2,1,6,""),2+(LEN(B2)=18)*2))

??從混合字符串中取重量:=LOOKUP(9E+307,--LEFT(B2,ROW($1:$10)))*C2

??將金額分散填充:=LEFT(RIGHT("?￥"&$A2*100,13-COLUMN()))

??提取成績并計算平均:{=AVERAGE(MID(A2:A7,4,LEN(A2:A7)-3)*1)}

??提取參賽選手姓名:=MID(A2,FIND("：",A2)+1,LEN(A2))

??從混合字符串中提取金額:=LOOKUP(307,--MID(B2,MIN(FIND({1;2;3;4;5;6;7;8;9},B2&123456789)),ROW($1:$99)))

??從卡機數據提取打卡時間:=730>--MID(A2,14,4)

??根據卡機數據判斷員工部門:=CHOOSE(MATCH(--RIGHT(A2,3),{1,38,14,11,8,21,43,9,28},0),"生產部","業務部","總務部","人事部","食堂","保衛部","采購部","送貨部","財務部")

??根據身份證號碼統計男性人數:{=SUM(MOD(LEFT(RIGHT(B2:B11,1+(LEN(B2:B11)=18))),2))}

??從漢字與數字混合字串中提取溫度數據:{=MAX(IFERROR(--RIGHT(LEFT(B2,LEN(B2)-1),ROW($1:$10)),0))}

??將字符串位數統一:{=TEXT(RIGHT(A2,LEN(A2)-1),"!"&LEFT(A2)&REPT(0,MAX(LEN(A$2:A$10))-1))}

??對所有人員按平均分排序:{=INDEX(A:A,RIGHT(LARGE(B$2:B$11*1000+ROW($2:$11),ROW()-1),3))}

??取金額的角位與分位叫:=--RIGHT(ROUND(A2*100,),2)

??從格式不規范的日期中取出日:=TRIM(RIGHT(SUBSTITUTE(A2,".","?",2),3))

??計算平均成績(忽略缺考人員):=ROUND(AVERAGE(B2:B10),2)

??計算90分以上的平均成績:{=ROUND(AVERAGE(IF(ISNUMBER(B2:B10)*(B2:B10>90),B2:B10)),2)}

??計算當前表以外的所有工作表平均值2:=AVERAGE(一班:五班!B:B)

??計算二車間女職工的平均工資:{=AVERAGE(IF((B2:B10="二車間")*(C2:C10="女"),D2:D10))}

??計算一車間和三車間女職工的平均工資:{=AVERAGE(IF((B2:B10="一車間")+(B2:B10="三車間")*(C2:C10="女"),D2:D10))}

??計算各業務員的平均獎金:{=AVERAGE(1500+300*(INT((C2:C11-80000)/10000)))}

??計算平均工資(不忽略無薪人員):=ROUND(AVERAGEA(B2:B10),2)

??計算每人平均出口量:{=AVERAGEA((C2:C11="A")*D2:D11)}

??計算平均成績，成績空白也計算:{=AVERAGEA(B2:B11*1)}

??計算二年級所有人員的平均獲獎率:{=TEXT(AVERAGEA(IF(LEFT(A2:A10,3)="二年級",B2:B10/C2:C10)),"0.00%")}

??統計前三名人員的平均成績:=AVERAGEA(LARGE(B2:B11,{1,2,3}))

??求每季度平均支出金額:=AVERAGEIF(B2:B9,"支出",C2)

??計算每個車間大于250的平均產量:=AVERAGEIF(B2:C11,">250")

??去掉首尾求平均:=AVERAGEIFS(B2:B11,B2:B11,">"&MIN(B2:B11),B2:B11,"<"&MAX(B2:B11))

??生產A產品且無異常的機臺平均產量:=AVERAGEIFS(C2:C11,B2:B11,"A",D2:D11,"")

??計算生產車間異常機臺個數:=COUNT(C2:C11)

??計算及格率:{=TEXT(COUNT(0/(B2:B11>=60))/COUNT(B2:B11),"0.00%")}

??統計屬于餐飲娛樂業的店名個數:{=COUNT(SEARCH({"小吃","酒吧","茶","咖啡","電影","休閑","網吧"},A2:A11))}

??統計各分數段人數:{=COUNT(0/((B$2:B$11>ROW(A6)*10)*(B$2:B$11<=ROW(A7)*10)))}

??統計有多少個選手:{=COUNT(0/(MATCH(B2:B11,B2:B11,)=(ROW(2:11)-1)))}

??統計出勤異常人數:=COUNTA(B2:B11)

??判斷是否有人缺考:=IF(COUNTA(B2:E10)=ROWS(B2:E10)*COLUMNS(B2:E10),"沒有","有")

??統計未檢驗完成的產品數:=COUNTBLANK(B2:B11)

??統計產量達標率:=TEXT(COUNTIF(B2:B11,">=800")/COUNT(B2:B11),"0.00")

??根據畢業學校統計中學學歷人數:=COUNTIF(B2:B11,"*中學")

??計算兩列數據相同個數:{=SUM(COUNTIF(A2:A11,B2:B11))}

??統計連續三次進入前十名的人數:{=SUM(COUNTIF(C2:C11,IF(COUNTIF(A2:A11,B2:B11),B2:B11)))}

??統計淘汰者人數:{=SUM(N(COUNTIF(A2:C11,A2:C11)=1))}

??統計區域中不重復數據個數:{=SUM(1/COUNTIF(B2:B8,B2:B8))}

??統計諾基亞、摩托羅拉和聯想已隹出手機個數:=SUM(COUNTIF(B2:B11,"*"&{"諾基亞","摩托羅拉","聯想"}&"*"))

??統計聯想比摩托羅拉手機的銷量高多少:{=SUM(COUNTIF(B2:B11,{"諾基亞*","*聯想*"})*{1,-1})}

??統計冠軍榜前三名:{=INDEX(B:B,SMALL(IF(COUNTIF(B$2:B$12,B$2:B$12)*((MATCH(B$2:B$12,B$2:B$12,)=ROW($2:$12)-1))>=LARGE(COUNTIF(B$2:B$12,B$2:B$12)*((MATCH(B$2:B$12,B$2:B$12,)=ROW($2:$12)-1)),3),ROW($2:$12)),ROW(A1)))}

??統計真空、假空單元格個數:=COUNTIF(成績!C2:C11,"=")

??對名冊表進行混合編號:=IF(RIGHT(B1)<>"班",ROW()-COUNTIF($B$1:B1,"??班"),TEXT(COUNTIF($B$1:B1,"??班"),"[DBNum2]0"))

??提取不重復數據5:{=INDEX(B:B,MATCH(0,COUNTIF($D$1:D1,B$2:B$11),0)+1)}

??中國式排名:{=SUM(IF(B$2:B$11>B2,1/COUNTIF(B$2:B$11,B$2:B$11)))+1}

??統計大于80分的三好學生個數:{=COUNTIFS(B2:B11,"三好學生",C2:C11,">80")}

??統計業績在6萬到8萬之間的女業務員個數:=COUNTIFS(B2:B11,"女",C2:C11,">60000",C2:C11,"<=800000")

??統計二班和三班數學競賽獲獎人數:=SUM(COUNTIFS(B2:B11,{"二班","三班"},C2:C11,"數學*"))

??根據身高計算各班淘汰人數:=SUM(COUNTIFS(B$2:B$11,E1,C$2:C$11,{"<160",">180"}))

??計算A列最后一個非空單元格行號:{=MAX((A:A<>"")*ROW(A:A))}

??計算女職工的最大年齡:{=MAX((B2:B11="女")*C2:C11)}

??消除單位提取數據:{=MAX(IFERROR(ABS(LEFT(A2,ROW($1:$100))),))*IF(LEFT(A2)="-",-1,1)}

??計算單日最高銷售金額:{=MAX(SUMIF(A2:A11,A2:A11,C2:C11))}

??查找第一名學生姓名:=INDEX(A2:A10,MATCH(MAX(B2:B10),B2:B10,))

??統計季度最高產值合計:{=MAX(SUBTOTAL(9,OFFSET(B2,,COLUMN(B:E)-2,ROWS(2:10),1)))}

??根據達標率計算員工獎金:=MAX((B2>{0,0.8,0.9,1,1.05})*{200,250,300,450,550})

??提取產品最后報價和最高報價:{=INDEX(C:C,MAX((A2:A11="B")*ROW(2:11)))}

??計算衛冕失敗最多的次數:{=MAX(FREQUENCY(ROW(2:11),((B2:B10="第一名")<>(B3:B11="第一名"))*ROW(2:10)))}

??低于平均成績中的最優成績:{=MAX(IF(B2:B11

??計算語文成績大于90分者的最高總成績:=DMAX(A1:E11,5,G1:G2)

??計算數學成績等于100分的男生最高總成績:=DMAX(A1:E11,"總分",B1:B2)

??根據下拉列表計算不同項目的最大值:=DMAX(A1:E11,G4,G1:G2)

??計算中間成績:=MEDIAN(B2:B11)

??顯示動態日期，但不能超過9月30日:=MIN("2008-9-30",TODAY())

??根據工作時間計算可休假天數:=MIN(SUM((B2={"A","B","C"})*{5,4,3})+(C2-1),10)

??確定最佳成績:=MATCH(MIN(B2:B11),B2:B11,)

??計算文具類產品和家具類產品最小利率:{=TEXT(MIN(IF(ISNUMBER(SEARCH("(?具類",A2:A11)),B2:B11)),"0.00%")}

??計算得票最少者有幾票:{=MIN(COUNTIF(B2:C11,B2:C11))}

??根據工程的難度系數計算獎金:=MIN(A2,1+(A2>1.3)*0.3)*500

??將科目與成績分開:{=MID(A2,MIN(IF(ISNUMBER(FIND(ROW($1:$9),A2)),FIND(ROW($1:$9),A2))),100)}

??計算五個班的第一名人員的最低成績:=MIN(SUBTOTAL(4,INDIRECT({"一","二","三","四","五"}&"班!B2:b11")))

??根據員工生產產品的廢品率記分:=MAX(MIN(6-(B2*100-5),10),0)

??統計售價850元以上的產品最低利率是多少:=DMIN(A1:D11,F4,F1:F2)

??統計文具類和廚具類產品的最低單價:=DMIN(A1:B11,2,D1:D2)

??第三個最小的成績:=SMALL(B2:B11,3)

??計算最后三名成績的平均值:=AVERAGE(SMALL(B2:B11,{1,2,3}))

??將成績按升序排列:{=SMALL(B$2:B$11,ROW(A1))}

??羅列三個班第一名成績:{=SMALL(IF(C$2:C$11="第一名",D$2:D$11),ROW(A1))}

??將英文月份名稱升序排列:{=INDEX(A$2:A$13,SMALL(IF(CODE($A$2:$A$13)=SMALL(CODE(A$2:A$13),ROW(A1)),ROW($1:$12)),COUNTIF(C$1:C1,CHAR(SMALL(CODE(A$2:A$13),ROW(A1)))&"*")+1))}

??查看產品曾經銷售的所有價位:{=IF(ROW(A1)>SUM(1/COUNTIF(B$2:C$11,B$2:C$11)),"",SMALL(B$2:C$11,1+COUNTIF(B$2:C$11,"<="&E1)))}

??羅列三個工作表B列最后三名成績:=SMALL(一班:三班!B:B,ROW(A1))

??第3個最小成績到第6個最小成績之間的人數:{=SUM((((SMALL(B2:D11,ROW(INDIRECT("1:"&COUNT(B2:D11))))>SMALL(B2:D11,{3,6}))*{1,-1})))}

??計算與第3個最大值并列的個數:{=SUM(--(B2:B11=LARGE(B2:B11,3)))}

??計算大于等于前10個最大產量之和:=SUMPRODUCT((B2:C11>LARGE(B2:C11,11))*B2:C11)

??按成績列出學生排行榜:{=INDEX(A$2:A$11,MATCH(LARGE(10-ROW($2:$11)+B$2:B$11*1000,ROW(A1)),10-ROW($2:$11)+B$2:B$11*1000,0))}

??最后一次獲得第一名是第幾屆:{=INDEX(A:A,LARGE((B2:B11="第一名")*ROW(2:11),1))}

??提取銷量的前三名的外銷產品名稱:{=LOOKUP(0,0/($B$2:$B$10*100+ROW($2:$10)=(LARGE(IF(RIGHT(A$2:A$10,3)="外銷)",B$2:B$10*100+ROW($2:$10)),ROW(A1)))),A$2:A$10)}

??哪種產品生產次數最多:{=TEXT(MODE(B2:B9*1),"00")}

??羅列出被投訴多次的工作人員編號:{=IFERROR(TEXT(MODE(IF(COUNTIF($D$1:D1,$B$2:$B$11)=0,$B$2:$B$11*1)),"00"),"")}

??對學生成績排名:=RANK(B2,B$2:B$11,0)

??計算兩列數值相同個數:=COUNT(RANK(B2:B11,C2:C11))

??查詢某人成績在三個班中的排名:成績{=LOOKUP(0,0/(E2:E11=H2),F2:F11)};名次=RANK(I2,(B2:B11,D2:D11,F2:F11),0)

??分別統計每個分數段的人員個數:{=FREQUENCY(B2:B11,D2:D5)}

??蟬聯冠軍最多的次數:{=MAX(FREQUENCY(ROW(B$2:B$11),(B$2:B$10<>B$3:B$11)*ROW(B$2:B$10)))}

??計算最多經過幾次測試才成功:{=MAX(FREQUENCY(ROW(2:11),(B2:B11="成功")*ROW(2:11)))}

??計算三個不連續區間的頻率分布:{=SUM(LOOKUP({1,3,5},ROW(1:5),FREQUENCY(B2:B11,{500,550,600,650})))}

??計算因密碼錯誤被鎖定幾次:{=COUNT(0/((FREQUENCY(ROW(2:12),(B2:B12<>"錯誤")*ROW(B2:B12))-1)>=3))}

??計算小學加初中人數及中專加大學人數:{=FREQUENCY((B2:B11<>"小學")*(B2:B11<>"初中"),0)}

??計算文本的頻率分布:{=FREQUENCY(CODE(B2:B11),CODE(D2:D5))}

??奪冠排行榜:{=IF(ROW(A1)>SUM(1/COUNTIF($B$2:$B$11,$B$2:$B$11)),"",INDEX($B$2:$B$11,MATCH(LARGE(FREQUENCY(MATCH($B$2:$B$11,$B$2:$B$11,),ROW($1:$9))-ROW($1:$10)%,ROW(A1)),FREQUENCY(MATCH($B$2:$B$11,$B$2:$B$11,),ROW($1:$9))-ROW($1:$10)%,)))}

??誰蟬聯冠軍次數最多:=INDEX(B2:B11,MATCH(MAX(FREQUENCY(ROW(2:11),(B2:B10<>B3:B11)*ROW(2:10))),FREQUENCY(ROW(2:11),(B2:B10<>B3:B11)*ROW(2:10)),))

??中國式排名:{=SUM(--(IF(FREQUENCY(B$2:B$11,B$2:B$11),B$2:B$11>B2)))+1}

??誰獲得第二名:{=INDEX(A:A,SMALL(IF(B$2:B$11=SMALL(IF(FREQUENCY($B$2:$B$11,$B$2:$B$11),$B$2:$B$11),2),ROW($2:$11),1048576),ROW(A1)))&""}

??記錄當前日期與時間:=TEXT(NOW(),"m月d日?h:m:s")

??確定是否已到加油時間:=TEXT(NOW()-B2,"H:m")>"5:30"

??國慶倒計時:=TEXT("10-1"-TEXT(NOW(),"mm-dd"),"00")

??統計發貨到收款天數:=ROUNDUP(IF(B2<>"",B2-A2,NOW()-A2),0)

??統計已到達收款時間的貨品數量:=COUNTIF(B2:B10,"<"&(TODAY()-30))

??本月需要完成幾批貨物生產:{=SUM(N(B2:B11=TEXT(TODAY(),"MMMM")))}

??計算本季度收款的合計:{=SUM(IF(ROUNDUP(B2:B11/3,0)=ROUNDUP(TEXT(TODAY(),"M")/3,0),C2:C11))}

??判斷今年是否閏年:=OR((MOD(TEXT(TODAY(),"yyyy"),4)=0)*(MOD(TEXT(TODAY(),"yyyy"),100)<>0),AND(MOD(TEXT(TODAY(),"yyyy"),{100,400})=0))

??計算2008年有多少個星期日:{=SUM(N(TEXT(DATE(2008,1,ROW(INDIRECT("1:"&("2008-12-31"-"2008-1-1")))),"AAA")="日"))}

??計算本月有多少天:=TEXT(DATE(YEAR(TODAY()),MONTH(TODAY())+1,0),"D")

??確定今年母親節的日期:=DATE(YEAR(TODAY()),5,14-WEEKDAY(DATE(YEAR(TODAY()),4,30),2))

??今年包含多少個星期:{=SUM(N(WEEKDAY(DATE(YEAR(TODAY()),1,ROW(INDIRECT("1:"&(365+(DAY(DATE(YEAR(TODAY()),2,29))=29))))),2)=7))+(WEEKDAY(DATE(YEAR(TODAY()),1,365+(DAY(DATE(YEAR(TODAY()),2,29))=29)))<7)}

??將身份證號碼轉換成出生日期序列:=DATE(MID(B2,7,2+(LEN(B2)=18)*2),MID(B2,9+(LEN(B2)=18)*2,2),MID(B2,11+(LEN(B2)=18)*2,2))

??計算建國多少周年:=YEAR(TODAY())-1949

??計算2000年前電腦培訓平均收費:{=AVERAGE(IF(YEAR(A2:A11)<2000,B2:B11))}

??計算今天離本年度最后一天的天數:=(YEAR(TODAY())&"-12-31")-TODAY()

??計算本月需要交貨的數量:{=SUM((MONTH(B2:B11)=MONTH(TODAY()))*C2:C11)}

??計算8月份筆筒和毛筆的進貨數量:{=SUM(IF(MONTH(A2:A11)=8,IF((B1:H1="筆筒")+(B1:H1="毛筆"),B2:H11)))}

??計算交貨起止月:{=MIN(MONTH(B2:B11))&"月-"&MAX(MONTH(B2:B11))&"月"}

??有幾個月要交貨:{=COUNT(0/FREQUENCY(MONTH(B2:B11),MONTH(B2:B11)))}

??哪幾個月要交貨:{=IFERROR(SMALL(IF(FREQUENCY(MONTH(B$2:B$11),MONTH(B$2:B$11)),MONTH(B$2:B$11)),ROW(A1))&"月","")}

??統計家具類和文具類產品在1月份的出庫次數:{=SUM((B2:B11={"文具類","家具類"})*(IF(C2:C11>0,MONTH(C2:C11)=1)))}

??計算今年平均每月天數:{=AVERAGE(DAY(DATE(YEAR(TODAY()),ROW(2:13),0)))}

??計算員工轉正時間:=DATE(YEAR(B2),MONTH(B2)+3+(DAY(B2)>15),16)

??統計本月下旬出庫數量:{=SUM(C2:C11*(DAY(B2:B11)>20))}

??計算生產速度是否達標:=YEARFRAC(C2,D2)<=(E2/B2)

??計算截至今天的利息:=B2*D2*YEARFRAC(C2,NOW())

??計算還款日期:=TEXT(EDATE(B2,C2),"yy-mm-dd")

??計算2008年到2010年共有多少天:{=SUM(DAY(EDATE("2008-1-31",ROW(1:36)-1)))}

??提示合同續約:=TEXT(EDATE(B2,C2*12)-TODAY(),"[<0]合同過期;[<=10]即將到期;;")

??計算借款日期到本月底的天數:=EOMONTH(B2,MONTH(TODAY())-MONTH(B2))-B2

??計算本季度天數:=SUM(DAY(EOMONTH(NOW(),{0,1,2}-MOD(MONTH(NOW())-1,3))))

??生成工資結算日期:=TEXT(EOMONTH(B2,0)+1,"e年M月D日")

??統計兩倍工資的加班小時數:=SUMPRODUCT(--(TEXT(ROW(INDIRECT(B2&":"&EOMONTH(B2,0))),"AAA")="六"))*8

??計算員工工作天數和月數:=DATEDIF(B2,C2,"M")

??根據進廠日期計算員工可假休天數:=MIN(IF(DATEDIF(B2,TODAY(),"M")<6,0,IF(DATEDIF(B2,TODA

??根據身份證號碼計算年齡(包括年月天):=CONCATENATE(DATEDIF(TEXT(MID(B2,7,LEN(B2)/2-1),"#-00-00"),TODAY(),"Y"),"年",DATEDIF(TEXT(MID(B2,7,LEN(B2)/2-1),"#-00-00"),TODAY(),"YM"),"月",DATEDIF(TEXT(MID(B2,7,LEN(B2)/2-1),"#-00-00"),TODAY(),"MD"),"天")

??計算年資:=10*MIN(DATEDIF(B2,TODAY(),"y"),15)+MAX(DATEDIF(B2,TODAY(),"y")-15,0)*5

??計算臨時工的工資:=ROUND(TIMEVALUE(SUBSTITUTE(SUBSTITUTE(B2,"分",""),"小時",":"))/(8/24)*50,)

??計算本日工時工資:=(HOUR(C2-TIMEVALUE("8:00"))-1-ROUNDUP(B2-TIMEVALUE("8:00"),0))*6

??計算8：00一16：00的平均電壓:{=AVERAGE(IF((DAY(A2:A11)=8)*(HOUR(A2:A11)>=8)*(HOUR(A2:A11)>=16),B2:B11))}

??計算工作時間，精確到分鐘:=HOUR(C2)+MINUTE(C2)/60-HOUR(B2)-MINUTE(B2)/60-D2+24*(C2

??根據完工時間計算獎金:=IF(HOUR(B2)>=18,-(ROUNDUP((HOUR(B2-"18:00")*60+MINUTE(B2))/30,0))*3,(ROUNDDOWN((HOUR("18:00"-B2)*60+60-MINUTE(B2))/30,0))*3)

??計算工程時間:=SUMPRODUCT(MINUTE(B2:B11)+(SECOND(B2:B11)>0))

??計算今天是星期幾:=WEEKDAY(NOW(),2)

??匯總星期日的支出金額:{=SUM((WEEKDAY(A2:A11,2)=7)*(B2:B11="支出")*C2:C11)}

??匯總第一個星期的出庫數量:{=SUM(OFFSET(A2,,MIN(IF(WEEKDAY(B1:P1,2)=1,COLUMN(B:P))),,7))}

??計算每日工時工資:=8*5*IF(WEEKDAY(A2,2)<6,1,1.5)+(B2-8)*5*1.5

??計算指定日期所在月份有幾個星期日:{=SUM(N(WEEKDAY(DATE(YEAR(A2),MONTH(A2),ROW(INDIRECT("1:"&DAY(EOMONTH(A2,0))))))=1))}

??按周匯總產量:{=SUM(((WEEKDAY($B1,2)-WEEKDAY($B1:$AF1,2))+(COLUMN($B1:$AF1)-1)=(1+(COLUMN(A1)-1)*7))*$B2:$AF2)}

??按周匯總進倉與出倉數量:{=SUM(((WEEKDAY($B1,2)-WEEKDAY($B1:$BK1,2))+INT((COLUMN($B1:$BK1))/2)=(1+(INT((COLUMN(A1)+1)/2)-1)*7))*$B3:$BK3*($B2:$BK2=B7))}

??羅列本月休息日:{=IFERROR(SMALL(IF(WEEKDAY(DATE(YEAR(NOW()),MONTH(NOW()),ROW(INDIRECT("1:"&DAY(EOMONTH(NOW(),0))))),2)=2,DATE(YEAR(NOW()),MONTH(NOW()),ROW(INDIRECT("1:"&DAY(EOMONTH(NOW(),0)))))),ROW()),"")}

??計算周末獎金補貼:=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(B2&":"&C2))-1,2)>5))*10

??羅列值班日期:{=MIN(IF(WEEKDAY(DATE(2008,ROW(),ROW($1:$31)),2)=7,DATE(2008,ROW(),ROW($1:$31))))}

??計算本月加班時間:{=SUM((MOD(MOD(WEEKDAY(DATE(YEAR(NOW()),MONTH(NOW()),ROW(INDIRECT("1:"&DAY(EOMONTH(NOW(),0))))),2),7),2)={1,0})*{3,2})}

??今天是本年度第幾周:=WEEKNUM(TODAY())

??本月包括多少周:=WEEKNUM(EOMONTH(NOW(),0),2)-WEEKNUM((EOMONTH(NOW(),-1)+1),2)+1

??羅列第30周日期:{=TEXT(SMALL(IF(WEEKNUM(DATE(YEAR(NOW()),1,ROW($1:$366)),2)=30,DATE(YEAR(NOW()),1,ROW($1:$366))),ROW(A1)),"YYYY-MM-DD")}

??統計某月第四周的支出金額:{=SUM((WEEKNUM(A2:A11*1,1)-WEEKNUM(YEAR(A2:A11)&"-"&MONTH(A2:A11)&"-1")+1=4)*B2:B11)}

??判斷本月休息日:{=(SUM(N(WEEKNUM(ROW((INDIRECT((EOMONTH(NOW(),-1)+1)&":"&EOMONTH(NOW(),0)))),2)-WEEKNUM(EOMONTH(NOW(),-1)+1,2)+1=5))>3)+4}

??計算離職日期:=WORKDAY(A2,5,{"2008-10-1","2008-10-2","2008-1-3"})

??計算工程完工日期:{=WORKDAY(A2,B2,EOMONTH(A2,ROW(INDIRECT("1:"&INT(B2/30*2)))))}

??計算2008年第一季度有多少個工作日:=NETWORKDAYS(EOMONTH(NOW(),-MONTH(NOW()))+1,EOMONTH(NOW(),3-MONTH(NOW())),{"2008-2-7","2008-2-8","2008-2-9"})

??計算2008年第一季度有多少個非工作日:=EOMONTH(NOW(),3-MONTH(NOW()))-EOMONTH(NOW(),-MONTH(NOW()))-NETWORKDAYS(EOMONTH(NOW(),-MONTH(NOW()))+1,EOMONTH(NOW(),3-MONTH(NOW())),{"2008-2-7","2008-2-8","2008-2-9"})

??計算今天離國慶節還有多少個工作日:=NETWORKDAYS(TODAY(),DATE(YEAR(TODAY())+(TODAY()>DATE(YEAR(TODAY()),10,1)),10,1))

??填充12個月的月份名:=CONCATENATE("第",TEXT(ROW(A1),"[DBNum1]"),"月")

??產生“坐標”:=CHAR(64+COLUMN(A1))

??檢查日倉庫報表日期是否正確:{=IF(SUM(N((11-RANK(A2:A11,A2:A11))=(ROW(2:11)-1)=FALSE)),"非遞增","遞增")}

??檢查字符串中哪一個字符出現次數最多:{=CHAR(MODE(IFERROR(CODE(MID(A2,ROW(1:16),1)),"")))}

??產生每兩行累加1的編號:=IF(ROW()=1,1,IF(MOD(ROW(),3),COUNT(OFFSET(A$1,,,ROW()-1))+1,""))

??最后一次不及格是哪次測試:{=INDEX(A:A,MAX((B2:B11<60)*ROW(2:11)))}

??計算第11名到第30名學員的平均成績:{=AVERAGE(IF(RANK(B2:B101,B2:B101)=TRANSPOSE(ROW(11:30)),B2:B101))}

??計算成績排名，不能產生并列名次:=SUMPRODUCT(--((A$2:A$15=A2)*(($C$2:$C$15)+1/ROW($C$2:$C$15))>C2+1/ROW(2:2)))+1

??計算第一次收入金額大于30元時的金額是多少:=INDEX(B:B,MIN(IF((A2:A11=A2)*(B2:B11>30),ROW(2:11))))

??計算扣除所有扣款后的最高薪資:{=MAX(B2:B10-MMULT(C2:G10*1,ROW(1:5)^0))}

??對班級和成績升序排列:{=1*MID(SMALL(1*($A2:$A12&TEXT($B2:$B12,"000")),ROW($A$2:$A$12)-1),{1,2},{1,3})}

??羅列今日銷售的諾基亞手機型號:{=T(INDEX(B:B,SMALL(IF(ISERROR(FIND("諾基亞",B$2:B$11)),10^6,ROW($2:$11)),ROW(1:1))))}

??統計圖書數量:{=IF(B2="","",MIN(IF(B3:B$13<>"",ROW(3:$13),13))-ROW())}

??羅列第一名學生姓名:{=T(INDEX(A:A,SMALL(IF($B$2:$B$11=MAX(B$2:B$11),ROW($2:$11),12),ROW(A1))))}

??羅列1到1000之間的質數:{=INDEX(A:A,SMALL(IF(A$2:A$1000<>"",ROW($2:$1000),1001),ROW(A1)))&""}

??判斷某數是否為質數:{=IF(A2<2,"非質非合",IF(SMALL(IF(MOD(A2,ROW(INDIRECT("1:"&A2)))=0,ROW(INDIRECT("1:"&A2))),2)=A2,"質數","合數"))}

??計算某個數的約數個數及羅列所有約數:約數個數{=COUNT(0/(MOD(A2,ROW(INDIRECT("1:"&A2)))=0))};羅列約數{=IFERROR(SMALL(IF(MOD(A$2,ROW(INDIRECT("1:"&A$2)))=0,ROW(INDIRECT("1:"&A$2))),ROW(A1)),"")}

??將六個號碼組合成一個:{=SUM(B1:B6*10^(2*(ROWS(B1:B6)-ROW(1:6))))}

??將每個人的貸款重新分組:{=INDEX($C:$C,SMALL(IF($A$2:$A$11=$E2,ROW($2:$11),ROWS($1:$12)),COLUMN(A1)))}

??檢測每個志愿是否與之前的重復:=MATCH(B2,$B$2:$B$10,)<>ROWS($2:2)

??將列標轉換成數字:=COLUMN(INDIRECT(A2&1))

??重組人事資料表:=REPLACE(INDIRECT("B"&1+(ROW(A1)-1)*4+COLUMN(A:A)),1,LEN(D$1)+1,"")

??班級成績查詢:{=INDEX($B:$E,SMALL(IF($A$2:$A$12=$H$2,ROW($2:$12),ROWS($1:$12)+1),ROW(A1)),COLUMN(A1))&""}

??羅列每日缺席名單:{=INDEX(全體成員!$1:$1,SMALL(IF(COUNTIF($B2:$K2,全體成員!$A$1:$M$1)=0,COLUMN($A:$M),16384),COLUMN(A1)))&""}

??計算所有人的一周產量并排名:{=INDEX(1:1,RIGHT(LARGE(SUBTOTAL(9,OFFSET($A2:$A8,,COLUMN($B:$J)-1,,))*10+COLUMN($B:$J)-1,COLUMN(A1)))+1)}

??將金額分散填充，空位以“-”占位:=MID(TEXT(INT($A2*100),REPT("-",9-LEN(INT($A2)))&REPT(0,LEN(INT($A2))+1)),COLUMNS($A:A),1)

??提取引用區域右下角的數據:=INDIRECT(ADDRESS(ROW(B3:D7)+ROWS(B3:D7)-1,COLUMN(B3:D7)+COLUMNS(B3:D7)-1))

??整理成績單:=INDIRECT(CHAR(ROWS($1:22)*3)&COLUMN())

??合并三個工作表的數據:=INDIRECT(CHOOSE(MOD(ROW(A2)-1,3)+1,"一年級!A"&INT((ROW(A3))/3)+1,"二年級!A"&INT((ROW(A3))/3)+1,"三年級!A"&INT((ROW(A3))/3)+1))

??多區域計數:=SUM(COUNTIF(INDIRECT({"C2:C11","F2:F11","I2:I11"}),"<60"))

??求積、求和兩相宜:=SUM(IF(C2="",INDIRECT("E"&LOOKUP(1,0/ISERROR((0/$C$1:C1="")),ROW($C$2:C2))&":E"&(ROW()-1)),C2*D2))

??計算五個工作表最大平均值:{=MAX(SUBTOTAL(1,INDIRECT({"一","二","三","四","五"}&"班!B2:b11")))}

??按卡號中的英文及數值排序:{=INDIRECT("A"&MOD(SMALL(CODE(B$2:B$11)*10000+MID(B$2:B$11,2,9)*100+ROW($2:$11),ROW(B1)),100))}

??多行多列取唯一值:{=IF(OR((B$2:D$5<>"")*(COUNTIF(F$1:F1,B$2:D$5)=0)),INDIRECT(TEXT(MIN(IF((B$2:D$5<>"")*(COUNTIF(F$1:F1,B$2:D$5)=0),ROW(B$2:D$5)*1000+COLUMN(B:D))),"r0c???"),),"")}

??羅列三個表中的最大值:{=SUBTOTAL(4,INDIRECT({"A組";"B組";"C組"}&"!B2:B11"))}

??將三列課程轉換成單列且忽略空值:{=INDIRECT(TEXT(SMALL(IF($B$2:$D$7<>"",ROW($2:$7)*1000+1,1048576001),ROW(A1)),"r#c000"),)&""}

??羅列兩個正整數的所有公約數:{=IFERROR(SMALL(IF((MOD(A$2,ROW(INDIRECT("1:"&GCD(A$2:B$2))))=0)*(MOD(B$2,ROW(INDIRECT("1:"&GCD(A$2:B$2))))=0),ROW(INDIRECT("1:"&GCD(A$2:B$2)))),ROW()-1),"")}

??B列最大值的地址:{=ADDRESS(MAX(IF(B2:B11=MAX(B2:B11),ROW(2:11))),2)}

??記錄最后一次銷量大于3000的地址:{=ADDRESS(MOD(MAX((IF(ISNUMBER(B2:D7),B2:D7,0)>3000)*ROW(B2:D7)+(IF(ISNUMBER(B2:D7),B2:D7,0)>3000)*COLUMN(B2:D7)*1000),1000),INT(MAX((IF(ISNUMBER(B2:D7),B2:D7,0)>3000)*ROW(B2:D7)+(IF(ISNUMBER(B2:D7),B2:D7,0)>3000)*COLUMN(B2:D7)*1000)/1000))}

??根據下拉列表引用不同工作表的產量:=INDIRECT(ADDRESS(11,2,1,1,D1))

??根據下拉列表羅列班級成績第一名姓名:{=IFERROR(INDIRECT(ADDRESS(LARGE(((INDIRECT(D$1&"!B2:B10")=MAX(INDIRECT(D$1&"!B2:B10")))*ROW($2:$10)),ROW(A1)),1,1,1,D$1)),"")}

??查詢成績:=OFFSET(A1,MATCH(F1,A2:A11,0),MATCH(G1,B1:D1,0))

??在具有合并單元格的A列產生自然數編號:=1+COUNT(OFFSET($A$2,,,ROW()-2,))

??引用合并區域時防止產生0值:=IF(A1<>"",A1,OFFSET(B1,-1,))

??計算10屆運動會中有幾次破紀錄:=SUMPRODUCT(N(SUBTOTAL(5,OFFSET(B2,,,ROW(2:10)))

??計第奎續三天之總產量大于等于25萬元的次數:=SUMPRODUCT(N(SUBTOTAL(9,OFFSET($B$1,ROW(1:10)-1,,3))>=25))

??進、出庫合計查詢:=SUM(OFFSET(A1,E2,MATCH(G2&"總計",B1:C1,0),F2-E2+1))

??根據人數自動調整表格大小:{=IFERROR(OFFSET($E$1,SMALL(IF(F$2:F$5>=TRANSPOSE(ROW(INDIRECT("1:"&MAX(F$2:F$5)))),ROW($2:$5)-1),ROW(1:1)),),"")}

??累計數據:{=SUM(OFFSET(B$2,,,ROW()-1))}

??計算至少兩科不及格的學生人數:{=SUM(--(COUNTIF(OFFSET($B$1,ROW(2:11)-1,,,4),"<60")>=2))}

??列出成績最好的科目:{=OFFSET(A2,,SUM((MAX(SUBTOTAL(9,OFFSET(A2,1,ROW(1:4),4)))=SUBTOTAL(9,OFFSET(A2,1,COLUMN(A:D),4)))*COLUMN(B:E))-1)}

??計算及格率不超過50%的科目數:{=SUM(N(COUNTIF(OFFSET(A1,1,COLUMN(A:D),10,1),"<60")>=ROWS(2:11)/2))}

??羅列兩次未打卡人員:{=IFERROR(OFFSET(A$1,LARGE((COUNTIF(OFFSET(A$1,ROW($2:$11)-1,1,,4),"×")>=2)*ROW($2:$11),ROW(A1))-1,),"")}

??計算語文、英語、化學、政治哪科總分最高:=CHOOSE(MATCH(MAX(SUBTOTAL(9,OFFSET(A1,1,MATCH({"語文","英語","化學","政治"},$B$1:$G$1,0),10,))),SUBTOTAL(9,OFFSET(A1,1,MATCH({"語文","英語","化學","政治"},$B$1:$G$1,0),10,)),0),"語文","英語","化學","政治")

??連續三屆達到100的次數:=SUMPRODUCT(N(COUNTIF(OFFSET(B1,ROW(2:9)-1,,3,1),">=100")=3))

??羅列及格率最高的學生姓名:{=INDEX(A:A,SMALL(IF(MAX(COUNTIF(OFFSET(A$1,ROW($2:$11)-1,1,1,COLUMNS(B:G)),">=60"))=COUNTIF(OFFSET(A1,ROW($2:$11)-1,1,1,COLUMNS(B:G)),">=60"),ROW($2:$11),12),ROW(A1)))&""}

??計算Excel類圖書最多進貨量及書名:{=MAX(SUMIF(OFFSET(B1,ROW(2:11)-1,1,1,6),">=100")*(B2:B11="excel"))}

??計算Excel類圖書進貨最多的是哪一個月:{=INDEX(C1:H1,MATCH(MAX(SUMIF(B2:B11,"excel",OFFSET(C2,,COLUMN(C:H)-3,ROWS(2:11),1))),SUMIF(B2:B11,"excel",OFFSET(C2,,COLUMN(C:H)-3,ROWS(2:11),1)),0))}

??根據下拉列表中的時間和產品名計算銷量冠軍:{=INDEX(A2:A11,MATCH(MAX(OFFSET(C2,,MATCH(J2,C1:H1,0)-1,ROWS(2:11),)*(B2:B11=K2)),OFFSET(C2,,MATCH(J2,C1:H1,0)-1,ROWS(2:11),)*(B2:B11=K2),0))}

??根據下拉列表中的產品提取姓名與銷量:{=IFERROR(1/MOD(SMALL(IF(B2:B11=K1,1/SUBTOTAL(9,OFFSET(C2,ROW(2:11)-2,0,1,COLUMNS(C:H)))+ROW(2:11)),ROW(1:10)),1),"")}

??計算產量最高的季度:=TEXT(MATCH(MAX(SUBTOTAL(9,OFFSET(A1,{0,3,6,9},1,3))),SUBTOTAL(9,OFFSET(A1,{0,3,6,9},1,3)),0),"[DBNum1]0季度")

??分欄打印:=IF(ROW()=1,CHOOSE(MOD(COLUMN()-1,3)+1,資料!$A$1,資料!$B$1,""),IF(MOD(COLUMN(),3)=0,"",OFFSET(資料!$A$1,INT(COLUMN()/3)*9+ROW()-1,MOD(COLUMN(),3)-1,)))

??分類匯總:=IF(SUMIF(B$2:B$11,E2,C$2:C$11)=0,"",SUMIF(B$2:B$11,E2,C$2:C$11))

??分類匯總并排序:{=OFFSET(B$1,RIGHT(LARGE(IF(MATCH(B$2:B$11,B$2:B$11,)=ROW($2:$11)-1,SUMIF(B$2:B$11,B$2:B$11,C$2:C$11)*1000+ROW($2:$11),ROWS($1:$11)+1),ROW(1:1)),3)-1,)&""}

??工資查詢:{=IFERROR(OFFSET(D1,MATCH(F2&G2&H2,A2:A11&B2:B11&C2:C11,0),),G2&"無此人")}

??多表成績查詢:{=SUBTOTAL(9,OFFSET(INDIRECT(ADDRESS(1,MATCH(H1,1:1,0),1,1,{"一班";"二班";"三班"})),1,,ROWS(2:11),))}

??計算每個學生總分是否高于本班平均成績:{=SUM(C2:E2)>AVERAGE(IF((A2=A$2:A$11),SUBTOTAL(9,OFFSET(B$1,ROW($2:$11)-1,1,,COLUMNS(C:E)))))}

??計算每個學生進入前三名的科目總數:{=SUM(N((RANK(N(OFFSET($B$2,ROW()-2,COLUMN(B:F)-2,1,1)),OFFSET($B$2,0,COLUMN(B:F)-2,ROWS($2:$11),1)))<=3))}

??計算高于單科平均值的科目總數:{=SUM(N(N(OFFSET($B$2,ROW()-2,COLUMN(B:F)-2,1,1))>SUBTOTAL(1,OFFSET($B$2,0,COLUMN(B:F)-2,ROWS($2:$11),1))))}

??羅列平均成績倒數三名的班級:{=OFFSET(A1,MATCH(SMALL(SUBTOTAL(1,OFFSET(A1,ROW($2:$9)-1,1,1,COLUMNS(B:F)))*1000+ROW(2:9),ROW(1:3)),SUBTOTAL(1,OFFSET(A1,ROW($2:$9)-1,1,1,COLUMNS(B:F)))*1000+ROW(2:9),),)}

??將姓名重復三次:{=T(OFFSET(A$1,ROUNDUP(ROW(INDIRECT("1:"&ROWS(A$2:A$5)*3))/3,0),))}

??多表匯總金額:{=SUM(SUBTOTAL(6,OFFSET(INDIRECT({"華南區","華東區","華北區"}&"!B1:C1"),ROW(2:10)-1,)))}

??從單價表引用單價并匯總金額:{=SUM((N(OFFSET(G1,MATCH(A2:A7,F2:F13,),)))*B2:B7)}

??從單價表引用最新單價并匯總金額:{=SUM((N(OFFSET(F1,MATCH(A2:A7,D2:D13,)+(COUNTIF(D2:D13,A2:A7)-1),)))*B2:B7)}

??根據完工狀況匯總工程款:{=SUM(SUBTOTAL(9,OFFSET(C1,ROW(2:11)-1,,1,2))*(E2:E11=G2))}

??統計最后三天的平均銷量:{=SUBTOTAL(1,OFFSET(INDIRECT("B"&MAX((A:A<>"")*ROW(1:1048576))),,,-3,1))}

??重組培訓科目表:姓名=LOOKUP(ROW()-1,COUNTIF(OFFSET(B$1:G$1,,,ROW($1:$7)),"<>"),A$2:A$8)&"";科目=IFERROR(OFFSET(B$2,MATCH(H2,$A$2:$A$7,)-1,COUNTIF($H$2:H2,H2)-1),"")

??從多個產品相同單價的單價表中引用單價:=SUMPRODUCT(COUNTIF(OFFSET(A$2,ROW($2:$4)-2,0,1,4),G2)*E$2:E$4)*H2

??統計所有業務員銷售利潤并羅列排列榜:{=OFFSET(A1,MOD(LARGE(INT(SUBTOTAL(6,OFFSET(C2,ROW(C2:C11)-2,,,3)))*1000+ROW(2:11),ROW(2:11)-1),1000)-1,)}

??按季度引用不同價格并統計金額與累計:{=IF(A2<>"累計",LOOKUP(COUNTIF(OFFSET(A$1,1,0,ROWS($2:2),),"合計")+1,ROW($2:$5)-1,F$2:F$5)*B2,SUM(C1:C$2*(A1:A$2<>"累計")))}

??計算10個月中的銷售利潤并排名:{=OFFSET(A1,MOD(LARGE(INT(MMULT(SUBTOTAL(6,OFFSET(INDIRECT({"華東區","華南區","華北區","華中區","西南區"}&"!A1"),ROW(2:11)-1,1,1,3)),{1;1;1;1;1}))*1000+ROW(2:11),ROW(1:10)),1000)-1,)}

??計算五個地區銷售利潤:{=TRANSPOSE(MMULT({1,1,1,1,1,1,1,1,1,1},SUBTOTAL(6,OFFSET(INDIRECT({"華東區","華南區","華北區","華中區","西南區"}&"!A1"),ROW(西南區!$2:$11)-1,1,1,3)))*1000+ROW(2:11))}

??計算第幾輪銷量最高以及售貨員姓名:{=OFFSET(A1,RIGHT(MAX(SUBTOTAL(9,OFFSET(D1,5*(ROW(INDIRECT("1:"&CEILING(COUNTA(C:C)/5,1)))-1),,5))*10+ROW(INDIRECT("1:"&CEILING(COUNTA(C:C)/5,1)))))*5-1,)}

??提取組名及計算每組平均達標率:{=TEXT(SUBTOTAL(1,OFFSET(B1,((ROW(1:4))*2-1),,,8)),"0.00%")}

??判斷是否超過一半人達標率在90%以上:{=COUNTIF(OFFSET(B1,((ROW(1:4))*2-1),,,8),">=0.9")>COLUMNS(B:I)/2}

??分別計算每個班第一名的成績和姓名:名次{=MAX(SUBTOTAL(9,OFFSET(B$1,ROW($2:$31)-1,1,,COLUMNS(C:I)))*(B$2:B$31=K2))};名{=OFFSET(A$1,MOD(MAX((SUBTOTAL(9,OFFSET(B$1,ROW($2:$31)-1,1,,COLUMNS(C:I)))*1000+ROW($2:$31))*(B$2:B$31=K2)),1000)-1,)}

??計算哪一個月完成目標:=OFFSET(A1,LOOKUP(,1*(SUBTOTAL(9,OFFSET(B1,1,0,ROW(2:12)-1))>=200),ROW(2:12)),)

??有幾次連續三個月的平均值低于整體平均值:{=SUM(N((SUBTOTAL(9,OFFSET(B4,ROW(2:11)-2,,3,2

??計算10個月中的銷售利潤并排名:{=OFFSET(A1,MOD(LARGE(INT(MMULT(SUBTOTAL(6,OFFSET(INDIRECT({"華東區","華南區","華北區","華中區","西南區"}&"!A1"),ROW(2:11)-1,1,1,3)),{1;1;1;1;1}))*1000+ROW(2:11),ROW(1:10)),1000)-1,)}

??將表格轉置方向:{=TRANSPOSE(A1:E5)}

??對組數進行排名:{=MMULT(N(B2:B11*(IF(LEFT(C2:C11)="萬",10000,1))

??區分大小寫提取產品單價:{=MMULT((EXACT(B2:B11,TRANSPOSE(單價表!A2:A5)))*TRANSPOSE(單價表!B2:B5),{1;1;1;1})}

??區分大小寫查單價且統計三組總金額:{=MMULT(TRANSPOSE(SUBTOTAL(9,OFFSET(B1,ROW(2:11)-1,1,,5))*MMULT((EXACT(B2:B11,TRANSPOSE(單價表!A2:A5)))*TRANSPOSE(單價表!B2:B5),{1;1;1;1})),1*(A2:A11={"A組","B組","C組"}))}

??引用銷售金額高于200次數最多者:{=INDEX(A:A,RIGHT(MAX(MMULT((B2:H9>200)*1,TRANSPOSE(COLUMN(B:H)^0))*10+ROW(2:9))))}

??根據評委評分和權重分配統計最后得分:{=SUM(B2:F8*(A2:A8=B10)*TRANSPOSE(I2:I6))}

??羅列選手得分前三名的姓名:{=OFFSET($A1,RIGHT(LARGE(MMULT($B2:$F8*TRANSPOSE($I2:$I6),TRANSPOSE(COLUMN($B:$F)^0))*10^6+ROW(2:8),COLUMN(A1)),2)-1,,)}

??根據字母評語轉換得分:{=MMULT(TRANSPOSE(評語換算得分!A$2:A$11=TRANSPOSE(E2:E11))*1,評語換算得分!B$2:B$11)+SUBTOTAL(9,OFFSET(B2,ROW(2:11)-2,,,COLUMNS(B:D)))}

??多列、隔行數據匯總:{=SUM(MMULT(D2:G11,TRANSPOSE(COLUMN(D:G)^0))*(A2:A11="趙還珠"))}

??計算犯規低于3次的人數:{=SUM(N(MMULT(--(B2:B21=TRANSPOSE(B2:B21)),ROW(2:21)^0)={1,2})/{1,2})}

??提取姓名:=INDEX(B:B,ROW()*2)&""

??從電話簿中選擇性引用數據:=INDEX($A:$B,ROW(A1)*3-2,COLUMN(A:A))

??消除廠牌打印資料照片行:{=INDEX(A:A,SMALL(IF(MOD(ROW($1:$12),3)>0,ROW($1:$12),1048576),ROW(A1)))&""}

??羅列優秀員工:{=INDEX(A:A,MOD(SMALL(B$2:B$11*100+ROW($2:$11),ROW(8:8)),100))}

??插入空行分割數據:=IF(MOD(ROW(),3)>0,INDEX(A:A,ROW(A2)*2/3),"")

??僅僅提取通訊錄中四分之三信息:=INDEX(A:B,ROW(A2)*2/3,(MOD(ROW(A3),3)+1)/3+1)

??羅列12月中產量倒數第一名次數最多者名單:{=INDEX(B:B,SMALL(IF((COUNTIF(B$2:B$13,B$2:B$13)=MAX(COUNTIF($B$2:$B$13,$B$2:$B$13)))*(MATCH($B$2:$B$13,$B$2:$B$13,0)=ROW($2:$13)-1),ROW($2:$13),1048576),ROW(A1)))&""}

??按投訴次數升序排列客服姓名:{=INDEX(B:B,MOD(SMALL(IF(MATCH(B$2:B$12,B$2:B$12,)=ROW($2:$12)-1,COUNTIF(B$2:B$12,B$2:B$12)*10^5+IF(MATCH(B$2:B$12,B$2:B$12,)=ROW($2:$12)-1,ROW($2:$12),9999999),9999999),ROW(A1)),10^5))&""}

??計算60分到95分之間的人員個數:=INDEX(FREQUENCY(B2:B11,{60,95}),2)

??羅列導致產品不良的主因:{=IFERROR(T(INDEX($A:$A,SMALL(IF($B$2:$B$11=LARGE(IF(FREQUENCY($B$2:$B$11,$B$2:$B$11),$B$2:$B$11),ROW(A1)),ROW($2:$11)),COLUMN(A1)))),"")}

??按身高對學生排列座次表:{=INDEX($A:$A,MOD(SMALL($C$2:$C$49*1000+ROW($2:$49),(ROW(A1)-1)*6+MOD(COLUMN(A1)-1,6)+1),1000))}

??重組教師授課表:{=INDEX(班級!$A:$A,SMALL(IF(班級!$B$2:$D$11=$A3,ROW($2:$11),1048576),COLUMN(C$1)))&""}

??提取三個不規則區域的交集:{=INDEX($B:$B,SMALL(IF(COUNTIF(C組!$B$2:$I$2,$B$2:$B$9)*COUNTIF(B組!$C$2:$D$4,$B$2:$B$9),ROW($B$2:$B$9),10),ROW(A4)))&""}

??不區分大小寫查找單價:=VLOOKUP(B2,單價表!A$2:C$11,3,0)*C2

??亂序資料表中查找多個項目:=VLOOKUP($B2,單價表!$A$2:$E$11,MATCH(C$1,單價表!$A$1:$E$1,0),0)

??將得分轉換成等級:=VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)

??查找美元與人民幣報價:=VLOOKUP(B2,INDIRECT(E2&"報價!A2:B9"),2,0)

??多條件查找:{=VLOOKUP(A2&B2&C2,IF({1,0},資料表!A2:A11&資料表!B2:B11&資料表!D2:D11,資料表!C2:C11),2,0)}

??查找最后更新單價:{=VLOOKUP(10^16,--LEFT(VLOOKUP(B2,單價表!A:Z,COUNTA(INDIRECT("單價表!A"&MATCH(B2,單價表!A:A,0)&":Z"&MATCH(B2,單價表!A:A,0))),0),ROW($1:$16)),1)}

??查找雙列信息:{=VLOOKUP(A9,CHOOSE({3,2,1},A1:A6&B1:B6,C1:C6&D1:D6,E1:E6&F1:F6),{2,3},)}

??提取姓名拼音的首字母:=VLOOKUP(LEFT(A2),拼音,2)&VLOOKUP(MID(A2,2,1),拼音,2)&VLOOKUP(MID(A2,3,1),拼音,2)

??用不確定條件查找:{=VLOOKUP(A2&"",IF({1,0},IF(COUNTIF(資料表!A2:A10,A2)=0,資料表!B2:B10,資料表!A2:A10),資料表!E2:E10),2,0)}

??按學歷對姓名排序:{=VLOOKUP(MOD(SMALL(MATCH(B$2:B$10,{"大學";"高中";"初中";"小學"},0)*1000+ROW($2:$10),ROW(A1)),1000),IF({1,0},ROW($2:$10),A$2:A$10),2,0)}

??使用通配符進行查找:{=VLOOKUP("*"&A2&"*",IF({1,0},資料表!B$2:B$9,資料表!A$2:A$9),2,0)}

??多工作表查找最大值:{=TEXT(VLOOKUP(MAX(SUBTOTAL(9,INDIRECT(TEXT(ROW(1:6),"[DBNum1]")&"年級!B"&MATCH(D2,A:A,0)))),IF({1,0},SUBTOTAL(9,INDIRECT(TEXT(ROW(1:6),"[DBNum1]")&"年級!B"&MATCH(D2,A:A,0))),ROW(1:6)),2,0),"[DBNum1]")}

??對帶有合并單元格的區域查找年假天數:=VLOOKUP(F2,OFFSET(B2,MATCH(E2,A2:A13,0)-1,,4,2),2)

??查找某業務員在某季度的銷量:=HLOOKUP(G2,A1:E9,MATCH(H2,A:A,0),0)

??在同一行查找數據:{=HLOOKUP(MAX(A2:H2),IF({1;0},B2:H2,A2:G2),2,FALSE)}

??計算兩個產品不同時期的單價:=HLOOKUP(MONTH(A2),IF(B2="塑膠機",{0,3,8;25,19,18},{0,5,10;12.5,10,11}),2)

??多條件計算加班費:=TEXT(HOUR(B2)+HLOOKUP(MINUTE(B2),{0,20.0001,50.0001;0,0.5,1},2),"[>2]6;5")*HOUR(B2)+HLOOKUP(MINUTE(B2),{0,20.0001,50.0001;0,0.5,1},2)

??根據進廠日期計算有薪假天數:=HLOOKUP(DATEDIF(B2,TODAY(),"y"),{0,1,3,5,7,10;0,2,3,5,7,10},2)

??制作準考證:=HLOOKUP(B2,學生檔案庫!$1:$11,ROUNDUP(COLUMN()/5,0)+1+INT(ROW()/7)*2,FALSE)

??不區分大小寫判斷兩列相同數據個數:{=COUNT(MATCH(A2:A11,B2:B11,0))}

??按漢字評語進行排序:{=INDEX(A:B,MOD(SMALL(MATCH($B$2:$B$12,排名標準!$A$2:$A$9,)*100+ROW($B$2:$B$12),ROW(2:12)-1),100),{1,2})}

??提取A列最后一個數據:{=INDIRECT("A"&(MATCH(1,0/(A:A<>""))))}

??提取字符串中的漢字:{=MID(A2,MATCH(1,1/(MID(A2,ROW($1:$99),1)>="啊"),),SUM(MATCH({1,2},1/(MID(A2,ROW($1:$99),1)>="啊"),{0,1})*{-1,1})+1)}

??將文件號中的中文大寫轉小寫:{="第"&TEXT(SUM((MATCH(MID(A2,{2,3,4},1),TEXT(ROW($1:$10)-1,"[DBNum2]"),0)-1)*{100,10,1}),"000")&"號文件"}

??計算補課科目總數:{=COUNT(0/(MATCH(B2:B8,B2:B8,0)=ROW(2:8)-1))}

??產生混合編號:=TEXT(COUNTIF(C$1:C1,"*"),"[DBNum2]")&TEXT(ROW()-MATCH("々",C$1:C1),"(000);;")

??提取遲到次數最多者姓名:=INDEX(B2:B11,MODE(MATCH(B$2:B$11,B$2:B$11,0)))

??羅列多次遲到者姓名:{=IFERROR(INDEX(B$2:B$11,MODE(IF(COUNTIF(D$1:D1,B$2:B$11)=0,MATCH(B$2:B$11,B$2:B$11,0)))),"")}

??區分、不區分大小寫統計字符個數:{=COUNT(0/(MATCH(MID(A2,ROW($1:$100),1),MID(A2,ROW($1:$100),1),0)=ROW($1:$100)))-1}

??按金、銀、銅牌排名次:{=MATCH(B2:B11+C2:C11%+D2:D11%%,LARGE(B2:B11+C2:C11%+D2:D11%%,ROW(2:11)-1),0)}

??按班級插入分隔行:{=INDEX(A:B,MOD(SMALL(IF({1,0},ROW(2:11)*1001,IF(ROW(2:11)-1=MATCH(A2:A11,A2:A11,0),((MATCH(A2:A11,A2:A11,)+COUNTIF(A2:A11,A2:A11))*1000+100),1048576)),ROW(1:100)),1000),{1,2})&""}

??統計一、二班舉重參賽人員數:{=COUNT(MATCH(B2:B11&C2:C11,{"一班","二班"}&"舉重",))}

??累計銷量并列出排行榜:{=OFFSET($B$1,MATCH(1,N(MAX(IF(COUNTIF($D$1:D1,B$2:B$12)=0,SUMIF(B$2:B$12,B$2:B$12,C$2:C$12)))=IF(COUNTIF($D$1:D1,B$2:B$12)=0,SUMIF(B$2:B$12,B$2:B$12,C$2:C$12))),),)&""}

??利用公式對入庫表進行數據分析:{=INDEX(B:B,SMALL(IF(MATCH(B$2:B$200,B$2:B$200,0)=ROW($2:$200)-1,ROW($2:$200),65536),ROW(A1)))&""}

??羅列每個地區的獲獎人員姓名:{=IFERROR(INDEX($A:$A,MATCH(1,(COUNTIF(E$1:E1,$A$2:$A$10)=0)*($B$2:$B$10=E$1),)+1),"")}

??對合并區域進行數據查詢:=OFFSET(B1,MATCH(G2,A2:A13,0)-1+MATCH(H2,{"冰箱","空調","洗衣機"},0),MATCH(I2,C1:E1,0))

??將一維人事資料表轉二維:{=REPLACE(IFERROR(OFFSET($A$1,MATCH(C$1:F$1&"：*",IF(COUNTIF(OFFSET(A$1,,,ROW($1:$42)),"")=ROW()-2,A$1:A$42),0)-1,),""),1,LEN(C$1:F$1)+1,"")}

??區分大小寫查找單價:{=INDEX(B:B,MATCH(0,0/EXACT(E1,A1:A8),0))}

??根據姓名查找左邊的身份證號:=LOOKUP(E2,B2:B9,A2:A9)

??將中文大寫編號轉換成阿位伯數字小寫:=TEXT(LOOKUP(1,0/(B2=TEXT(ROW($1:$1000),"[DBNum2]000")),ROW($1:$1000)),"000")

??將姓名按拼音升序排列:{=LOOKUP(0,0/(ROW(A1)=MMULT(N($A$2:$A$11>=TRANSPOSE($A$2:$A$11)),ROW($2:$11)^0)),A$2:A$11)}

??將酒店按星級降序排列:{=LOOKUP(ROUND(1/MOD(LARGE(LEN(B$2:B$10)+1/ROW($2:$10),ROW(A1)),1),0),ROW($2:$10),A$2:A$10)}

??計算某班六年中誰獲第一名次數最多:{=MAX(COUNTIF(B2:B7,B2:B7))}

??羅列每個名次的所有姓名:{=IFERROR(INDEX($A:$A,(SMALL(IF($B$2:$B$11=LARGE(IF(FREQUENCY($B$2:$B$11,$B$2:$B$11),$B$2:$B$11),ROW(A1)),ROW($2:$11)),COLUMN(A2)))),"")}

??提取新書的印刷批次:=LOOKUP(9E+307,--RIGHT(LEFT(A2,FIND("[",A2)-1),ROW($1:$99)))

??羅列2008年每月第一個及最后一個星期日:{=MIN(IF(WEEKDAY(DATE(2008,ROW(A1),ROW(INDIRECT("1:"&DAY(DATE(2008,ROW(A1)+1,0))))),2)=7,DATE(2008,ROW(A1),ROW(INDIRECT("1:"&DAY(DATE(2008,ROW(A1)+1,0)))))))}

??填補空白區:=LOOKUP(1,0/($A$2:A2<>""),A$2:A2)

??將字母轉換成評分:{=AVERAGE(LOOKUP(B2:I2,{"A","B","C","D","E"},{10,9.5,8,7,5}))}

??將字母轉換成評分并對選手排名:{=LOOKUP(MOD(LARGE(MMULT(LOOKUP($B$2:$I$7,{"A","B","C","D","E"},{10,9.5,8,7,5}),ROW($1:$8)^0)*10000+ROW($2:$7),ROW(A1)),10),ROW($2:$7),A$2:A$7)}

??標識各選手應得的獎牌:{=LOOKUP(SUM(N(IF(FREQUENCY(B$2:B$11,B$2:B$11),B$2:B$11,0)>B2))+1,ROW($1:$4),{"冠軍","亞軍","季軍",""})}

??計算各廠商參賽人數:{=IFERROR(LOOKUP(SMALL(IF(A$2:A$21<>"",ROW($2:$21)),ROW(A1)),ROW($2:$21),A$2:A$21)&":?"&MMULT(SMALL(IF(A$2:A$21<>"",ROW($1:$20),21),ROW(A1)+{0,1}),{-1;1}),"")}

??從品名信息中分別提取多段數值:=IFERROR(-LOOKUP(0,-MID($A2,FIND(B$1,$A2)+LEN(B$1),ROW($1:$100))),"--")

??反向查找數據:=LEN(A2)-LOOKUP(100,SEARCH(B2,A2,ROW($1:$99)))-LEN(B2)+2

??一級、二級分組編號:=TEXT(COUNTIF(B$1:B2,"第*"),"00")&TEXT(ROW()-LOOKUP(1,0/(LEFT(B$1:B2)="第"),ROW($1:2)),"[=0]?;000")

??計算購貨金額:{=LOOKUP(9E+307,--MID($A2,MATCH(0,0*MID($A2,ROW($1:$1000),1),0),ROW($1:$15)))*(LOOKUP(9E+307,--LEFT(REPLACE(A2,1,FIND("*",A2),""),ROW($1:$1000))))}

??誰是百米冠軍:=LOOKUP(0,0/(B2:B11=MIN(B2:B11)),A2:A11)

??從銷售記錄中提取銷量與單價并計算金額:{=LOOKUP(10^16,--RIGHT(REPLACE(A2,FIND("公斤",A2),100,""),ROW($1:$100)))*LOOKUP(10^16,--RIGHT(REPLACE(A2,FIND("元",A2),100,""),ROW($1:$100)))}

??根據比賽結果降序排列選手且標識名次:{=LOOKUP(SUM(N(COUNTIF(B$2:B$21,E2)<--IF(FREQUENCY(COUNTIF($B$2:$B$21,B$2:B$21),COUNTIF($B$2:$B$21,B$2:B$21)),COUNTIF($B$2:$B$21,B$2:B$21))))+1,ROW($1:$4),{"冠軍","亞軍","季軍",""})}

??計算每個職工的得分:=LOOKUP(,-FIND(B2,{"A**","A*","A","B**","B*","B","C**","C*","C","D"}),11-ROW($1:$10))

??查詢業務員的負責地區:{=T(INDEX(B:B,SMALL(IF(LOOKUP(ROW(A$2:A$11),IF(A$2:A$11<>"",ROW(A$2:A$11)),A$2:A$11)=$D$2,ROW(A$2:A$11),1048576),ROW(1:1))))}

??根據產量計算員工產量得分:{=LOOKUP(B2,{3,0.5}*(ROW($1:$11)-1))}

??根據員工得分轉換為相應的等級:=LOOKUP(B2,--REPLACE(等級與分值!B$2:B$6,FIND("-",等級與分值!B$2:B$6),10,""),等級與分值!A$2:A$6)

??提取產量冠軍的組別:=IF(COUNTA(B2:E2),LOOKUP(1,0/ISTEXT(B2:E2),B$1:E$1),"")

??區分工種和達標率計算獎金:=LOOKUP(C2*100,1*LEFT(達標與獎金標準!B$1:K$1,FIND("%",達標與獎金標準!B$1:K$1)-1),OFFSET(達標與獎金標準!B$1,MATCH(B2,達標與獎金標準!A$2:A$4,0),,,10))

??使用通配符查找所有符合條件的數據:{=IFERROR(LOOKUP(1,0/SEARCH("*醫院*",IF(COUNTIF($C$1:C3,A$2:A$12)=0,A$2:A$12,)),A$2:A$12),"")}

??分別提取身份證號碼中的年月日:=TEXT(TEXT(MID($A2,7,8),"0000-00-00"),"[DBNum1]"&CHOOSE(MATCH(B$1,{"年","月","日"},0),"YYYY年","M月","D日"))

??根據不良率判斷送貨品處理辦法:=CHOOSE((SUM(N(C2/B2>={0,0.005,0.01}))),"合格","允收","退貨")

??讓VLOOKUP函數在多區域查找:=VLOOKUP(A11,CHOOSE(MATCH(B11,{"一年級","二年級","三年級"},0),A1:B9,D1:E9,G2:H9),2,0)

??將區域互換位置:=VLOOKUP(E2&"",CHOOSE({2,1},A2:A9,C2:C9),2,0)

??跨表統計最大值:{=CHOOSE(MOD(MAX(SUBTOTAL(9,INDIRECT({"A組";"B組";"C組"}&"!B2:B10"))*100+{1;2;3}),100),"A組","B組","C組")}

??羅列所有參加田徑的人員:{=IFERROR(VLOOKUP(1,CHOOSE({1,2},--(COUNTIF(OFFSET(C$2,,,ROW($2:$11)-1),"田徑")=ROW(1:1)),A$2:A$11),2,),"")}

??計算今天是本月的上旬、中旬還是下旬:=CHOOSE(MIN(CEILING(DAY(TODAY())/10,1),3),?"上旬","中旬","下旬")

??建立文件目錄:=HYPERLINK("[E:\\產量表\\"&TEXT(ROW(1:1),"[DBNum1]")&"月產量表.xlsx]sheet1!A1",TEXT(ROW(1:1),"[DBNum1]")&"月產量表")

??鏈接“總表”中B列最大值單元格:{=HYPERLINK("#總表!B"&MAX((MAX(總表!B:B)=總表!B:B)*ROW(B:B)),"至總表B列最大值")}

??鏈接至B列最末的非空單元格:{=HYPERLINK("#B"&MAX(((B:B)<>"")*ROW(B:B)),"B列最后非空值")}

??選擇冠軍姓名:{=HYPERLINK("#"&TEXT(SUM(SMALL(IF(B2:B13=MAX(B2:B13),ROW(2:13)),ROW(INDIRECT("1:"&COUNTIF(B2:B13,MAX(B2:B13)))))*10^((ROW(INDIRECT("1:"&COUNTIF(B2:B13,MAX(B2:B13))))-1)*2)),REPT("A00!,",COUNTIF(B2:B13,MAX(B2:B13))-1)&"A00"),"得票冠軍")}

??選擇二年級曠課人員名單:{=HYPERLINK("#A"&MIN(IF(A2:A12="二年級",ROW(2:12)))&":B"&MAX(IF(A2:A12="二年級",ROW(2:12))),"二年級名單")}

??選擇產量最高工作表:{=HYPERLINK("#"&CHAR(64+MOD(MAX(SUBTOTAL(9,INDIRECT(CHAR(64+ROW(1:8))&"組!B2:B11"))*100+ROW(1:8)),100))&"組!A1","跳至最大產量組")}

??選擇打印區域:=HYPERLINK("#Print_Area",IF(ISERR(INDEX(Print_Area,1,1)),"未設置打印區","跳至打印區域"))

??計算期末平均成績:{=AVERAGE(IF(ISEVEN(COLUMN(B:I)-1),B3:I3))}

??提取期末成績明細:{=INDEX(成績表!1:1,SMALL(IF(ISEVEN(COLUMN($B:$I)-(ROW()<>1)),COLUMN($B:$I)),COLUMN(A1)))}

??提取每日累計出庫數和每日庫存數:日期=INDEX(A:A,ROW(A1)*2);累計出庫數{=SUM(ISODD(ROW(INDIRECT("2:"&(ROW(A1)*2)+1)))*OFFSET(C$1,1,,ROWS($1:1)*2))};每日庫存數{=SUM(SUMIF(OFFSET(B$1,1,,ROW(A1)*2),{"進庫","出庫"},C$2)*{1,-1})}

??根據身份證號碼匯總男、女職工總數:男{=SUM(--ISODD(MID(B2:B10,15,3)))};女{=SUM(--ISEVEN(MID(B2:B10,15,3)))}

??提取當前表打印區域地址:=IF(ISNA(VLOOKUP("蘋果",A2:B5,2,0)),10,LOOKUP(10^16,--LEFT(VLOOKUP("蘋果",A2:B5,2,0),ROW(1:100))))

??計算生產部人數和非生產部人數:生產部人數{=SUM((NOT(ISERR(FIND("車間",A2:A11)))*B2:C11))};非生產部人數{=SUM((ISERR(FIND("車間",A2:A11)))*B2:C11)}

??提取A、B列相同項與不同項:{=T(INDEX(A:A,SMALL(IF(NOT(ISERROR(MATCH(A$2:A$11,B$2:B$11,0))),ROW($2:$11),1048576),ROW(A1))))}

??計算產品體積:=IF(ISERROR(FIND("/",B2)),B2^3,PRODUCT(1*TRIM(MID(SUBSTITUTE(B2,"/",REPT("?",100)),{1,100,200},100))))

??引用單價并去除干擾符:=IF(ISNA(MATCH(B2,單價表!B$1:E$1,0)),"請更新單價",C2*LOOKUP(10^16,--LEFT(HLOOKUP(B2,單價表!B$1:E$2,2,0),ROW($1:$100))))

??查詢書籍在七年中的最高單價:{=IF(ISNA(MATCH(A10,A2:A8,0)),"書名錯誤",MAX(VLOOKUP(A10,A1:H8,COLUMN(B:H),0)))}

??根據計價單位查詢單價:=IF(ISNA(MATCH(B2,F$1:H$1,0)),"未設定匯率",C2*HLOOKUP(B2,F$1:H$2,2,0))

??數字、字母與漢字個數計算:數字個數{=SUM(--(ERROR.TYPE(INDIRECT("XFD"&MID(A2,ROW(INDI

??判斷錯誤類型:=LOOKUP(ERROR.TYPE(A2),ROW(1:7),{"空值錯誤";"被零除錯誤";"值錯誤";"無效的單元格引用";"無效的名稱";"數字錯誤";"值不可用"})

??羅列某運動員九次參賽成績:{=INDEX($1:$1,MAX(ISTEXT(B2:E2)*COLUMN(B:E)))}

??提取每年級第一名名單:=LOOKUP(1,0/ISTEXT(B2:E2),B$1:E$1)&":"&LOOKUP(1,0/ISTEXT(B2:E2),B2:E2)

??將按日期排列的銷售表轉換成按品名排列:{=IFERROR(VLOOKUP($A2,IF(MATCH(ROW($1:$15),IF(ISTEXT(日期!$A$1:$A$15),MATCH(日期!$A$1:$A$15,日期!$A$1:$A$15,0)))=MATCH(B$1,日期!$A$1:$A$15,0),日期!$B$1:$C$15),2,0),"")}

??按月份統計每個產品的機器返修數量:=SUMPRODUCT(ISNUMBER(FIND(F$2,$A$2:$A$11))*(TEXT($B$2:$B$11,"YM")=TEXT($E3,"YM"))*$C$2:$C$11)

??按文字描述求和:{=SUM(ISNUMBER(FIND(A$2:A$8,D2))*B$2:B$8)}

??按編碼計算庫存總數:{=SUM(ISNUMBER(FIND("/"&A$2:A$11*1&"/","/"&D2&"/"))*B$2:B$11)}

??從產品規格中提取直徑、長、寬:長(直徑)=LOOKUP(9.9E+307,--RIGHT(IF(ISNUMBER(FIND("×",A2)),REPLACE(A2,FIND("×",A2),100,""),A2),ROW($1:$100)));寬=IF(ISNUMBER(FIND("×",A2)),--RIGHT(A2,LEN(A2)-FIND("×",A2)),0)

??累計每日得分:=(N(C1)=0)*5+N(C1)+IF(B2>0,-B2,0.1)

??統計各班所有科目成績大于60分者人數:{=MMULT(N(TRANSPOSE(A2:A21)=H3:H6),N(COUNTIF(OFFSET(C2:F2,ROW(2:21)-2,),">=60")=4))}

??區分大小寫統計不重復值個數:{=SUM(N(MMULT(N(EXACT(A2:A11,TRANSPOSE(A2:A11))),ROW(2:11)^0)=TRANSPOSE(ROW(2:11)-1))/TRANSPOSE(ROW(2:11)-1))}

??累計每日庫存數:=N(G1)+SUM(OFFSET(C$1,ROW(A1)*2-1,,2))-SUM(OFFSET(D$1,ROW(A1)*2-1,,2))

??提取當前工作表名、工作簿名及存放目錄:工作表=REPLACE(CELL("filename"),1,FIND("]",CELL("filename")),"");工作簿=SUBSTITUTE(REPLACE(CELL("filename"),1,FIND("[",CELL("filename")),""),REPLACE(CELL("filename"),1,FIND("]",CELL("filename"))-1,""),"");存放目錄=REPLACE(CELL("filename"),FIND("[",CELL("filename")),100,"")

??提取第一次參賽取得最佳成績者姓名與成績:參賽者{=INDEX(A:A,MOD(MAX((IF(NOT(ISBLANK(C2:C11)),MATCH(A2:A11,A:A,0))=ROW(2:11))*C2:C11*100+ROW(2:11)),100))};成績{=MAX((IF(NOT(ISBLANK(C2:C11)),MATCH(A2:A11,A:A,0))=ROW(2:11))*C2:C11)}

??計算哪一個項目得票最多:{=INDEX({"A","B","C"},RIGHT(MAX(MMULT(TRANSPOSE(ROW(2:11)^0),N(IF(ISBLANK(B2:B11),"A",B2:B11)={"A","B","C"}))*10+{1,2,3})))}

??根據利率、存款與時間計算存款加利息數:=FV(B2,D2,-C2,0)

??計算七個投資項目相同收益條件下誰投資更少:{=MAX(PV(B2:B8,C2:C8,0,100000))}

??根據利息和存款數計算存款達到1萬元需要幾個月:=NPER(A2,0,-B2,C2)*12

??根據投資金額、時間和目標收益計算增長率:=RATE(B2,0,-A2,C2)

??根據貸款、利率和時間計算某段時間的利息:=CUMIPMT(B2/12,C2*12,A2,1,24,0)

??根據貸款、利率和時間計算需償還的本金:=CUMPRINC(B2/12,C2*12,A2,1,24,0)

??以固定余額遞減法計算資產折舊值:=DB(A$2,B$2,C$2,ROW(A1),12)

??以雙倍余額遞減法計算資產折舊值:=DDB(A$2,B$2,C$2,1,2)

??以年限總和折舊法計算折舊值:=SYD(A$2,B$2,C$2,ROW(A1))

??使用雙倍余額遞減法計算任何期間的資產折舊值:=VDB(A$2,B$2,C$2*12,7,12,2)

??獲取當前工作簿中工作表數量:=COLUMNS(sheets)&T(NOW())

??建立工作表目錄與超級鏈接:=IFERROR(HYPERLINK(INDEX(sheets,ROW(A1))&"!a1",REPLACE(INDEX(sheets,ROW(A1))&T(NOW()),1,FIND("]",INDEX(sheets,ROW(A1))),"")),"")

??選擇最后工作表的最后非空單元格:=HYPERLINK(INDEX(sheets,COLUMNS(sheets))&"!A"&LOOKUP(1,0/(INDIRECT(INDEX(sheets,COLUMNS(sheets))&"!A:A")<>""),ROW(1:1048576)))

??引用單元格數據同時引用格式:=IF(TODAY()>A2,"",TEXT(A2,格式))

??分別匯總當前表以外的所有工作表數據:AcSht=GET.CELL(62);sheets=GET.WORKBOOK(1);WorkBook=GET.CELL(66);{=IFERROR(REPLACE(INDEX(sheets,SMALL(IF(TRANSPOSE(sheets)<>AcSht,ROW(INDIRECT("1:"&COLUMNS(sheets)))),ROW(A2))),1,LEN(WorkBook)+2,""),"")}

??提取單元格的公式:名稱=GET.CELL(6,Sheet1!$B1)&T(NOW())

??羅列工作簿中所有名稱:{=IFERROR(INDEX(名稱,SMALL(IF(名稱<>"名稱",TRANSPOSE(ROW(INDIRECT("1:"&COLUMNS(名稱))))),ROW(A1))),"")}

??在任意單元格顯示當前頁數及總頁數:無拘無束的頁眉="第"&IF(橫向當前頁=1,縱向當前頁,橫向當前頁+縱向當前頁)&"頁/共"&總頁&"頁";縱向當前頁=IFERROR(MATCH(ROW(),GET.DOCUMENT(64))+1,1)

??提取單元格中的批注:批注=GET.OBJECT(12,?"備注?1")

??利用列表框篩選數據:篩選=IF(GET.OBJECT(78,"列表框?1"),GET.OBJECT(78,"列表框?1")*TRANSPOSE(ROW(sheet1!$A$2:$A$8)))

??判斷單元格是否被圖形對象覆蓋:=ADDRESS(ROW(INDIRECT(左上,0)),COLUMN(INDIRECT(左上,0)))&":"&ADDRESS(ROW(INDIRECT(右下,0)),COLUMN(INDIRECT(右下,0)))

??將單元格的公式轉換成數值:計算=EVALUATE(Sheet1!A3)

??將IP地址補足三位:IP地址=TEXT(EVALUATE("{"&SUBSTITUTE(Sheet1!A4,".",",")&"}"),"000.");QQ=TEXT(EVALUATE("{"&SUBSTITUTE(Sheet1!A4,".",".,")&"}"),"000")

??按分隔符取數并求平均:成績=EVALUATE(SUBSTITUTE("{"&SUBSTITUTE(Sheet1!$B2,"http://","/FALSE/")&"}","/",";"))

??根據產品規格計算體積:體積=EVALUATE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(Sheet1!XFD4,"(L)","*"),"(W)","*"),"(H)",""))

??計算減肥前后的三國差異:后=EVALUATE("{"&SUBSTITUTE(Sheet1!C3,":",",")&"}");?前=EVALUATE("{"&SUBSTITUTE(Sheet1!B3,":",",")&"}")

??計算各樓層空佘面積:面積=EVALUATE(SUBSTITUTE(SUBSTITUTE(Sheet1!XFD1,"[","*istext("""),"]",""")"))

??將數據分列，提取省市縣:分列=EVALUATE("{"""&SUBSTITUTE(SUBSTITUTE(Sheet1!$A5,"省","省"","""),"市","市"",""")&"""}")

??按圖書編號匯總價格:圖書=EVALUATE("{"""&SUBSTITUTE(Sheet1!B2,"/",""",""")&"""}")

??標識B列中的重復值:條件格式:=COUNTIF($B:$B,B1)>1

??將數據間隔著色:條件格式:=MOD(SUM(N($B$2:$B2<>$B$1:$B1)),2)=0

??隱藏錯誤值:單元格的公式:=VLOOKUP(A2,單價表!$A$2:$B$10,2,0)，條件格式:=ISERROR(B1)

??突顯前三個最大值:條件格式:=B2>LARGE($B$2:$F$10,4)

??將成績高于平均值的姓名標示“優等”:條件格式:=(B2>AVERAGE($B$2:$F$10))*MOD(COLUMN(),2)

??突顯奇數行:條件格式:=ISODD(ROW())

??突顯非數值:條件格式:=NOT(ISNUMBER(A2))*ISEVEN(COLUMN())

??B列中禁止輸入重復數據:數據有效性設置-自定義:=COUNTIF(B:B,B8)=1

??僅允許錄入英文姓名:數據有效性設置-自定義:=SUM(--(ERROR.TYPE(INDIRECT(MID(SUBSTITUTE(A2,"?",""),ROW(INDIRECT("1:"&LEN(SUBSTITUTE(A2,"?","")))),1)&1))=3))=LEN(SUBSTITUTE(A2,"?",""))

??強制錄入規范化的日期:數據有效性設置-自定義:=(LEN(A2)=8)*TEXT(A2,"#-00-00")

??建立動態下拉選單:定義名稱:水果=OFFSET(單價表!$A$1,,,COUNTA(單價表!$A:$A))

??建立二級下拉選單:定義名稱:省=OFFSET(參考區!$A$1,,,,COUNTA(參考區!$1:$1));市=OFFSET(參考區!$A$1,1,MATCH(Sheet1!$A$2,參考區!$1:$1,0)-1,COUNTA(OFFSET(參考區!$A$1,1,MATCH(Sheet1!$A$2,參考區!$1:$1,0)-1,1048575)))

??建立不重復的下拉選單:{=INDEX(A:A,SMALL(IF(COUNTIF(Sheet1!A$1:A$8,A$1:A$8)=0,ROW($1:$8),1048576),ROW(A2)))&""}?(生成不重復單位);定義名稱:=OFFSET(名單!$B$1,,,8-COUNTBLANK(名單!$B$1:$B$8))

??讓A列只能輸入質數:數據有效性設置-自定義:=OR(A2=2,A2=3,PRODUCT(MOD(A2,ROW(INDIRECT("2:"&?INT(A2^0.5))))))

??設置D列只能錄入男職工的姓名:數據有效性設置-自定義:=VLOOKUP(D2,A:B,2,0)="男"

??禁止錄入不完整的產品規格:數據有

??效性設置-自定義:=ISNUMBER(SEARCH("長?*寬?*高?*",B2))

??自動記錄進庫時間:=IF(ISBLANK(B2),"",IF(C2="",NOW(),C2))

??記錄歷史最高值:=MAX(B:B,D2)

??解一元二次方程:X+100=X^2+10

??以上就是excel使用函數公式教程，希望可以幫助到大家。

??解二元一次方程:X=10X=(100-5Y)/25,Y=Y/5=(200?+4X)/4

最后，小編給您推薦，金山毒霸“PDF轉化”，支持如下格式互轉：· Word和PDF格式互轉· Excel和PDF格式互轉· PPT和PDF格式互轉· 圖片和PDF格式互轉· TXT和PDF格式互轉· CAD和PDF格式互轉